Groovy 在斯波克能查到电话号码吗

有可能在Spock中获得模拟方法的调用次数吗？我想测试该方法是否被调用了特定次数，但每秒返回的值应该不同。下面的伪代码应该更具体地说明我想要什么：

void "My idea of a test" {
    when:
       ...
    then:
        10 * someService(_) >> {
             return theNumberOfTheCall % 2 ? SOME_VALUE : null // theNumberOfTheCall should illustrate my purpose
        }
// so the service will return [null, SOME_VALUE, null, SOME_VALUE, null ...]
}

---

Spock本身不会向mock方法传递大量调用，但可以利用

AtomicInteger

增加测试方法中定义的计数器。考虑下面的简单例子：

import spock.lang.Specification    
import java.util.concurrent.atomic.AtomicInteger

class InvocationCounterSpec extends Specification {

    def "should return different value depending on invocation counter"() {
        setup:
        final AtomicInteger counter = new AtomicInteger(0)
        final SomeService someService = Mock(SomeService)
        final SomeClass someClass = new SomeClass(someService)

        when:
        someClass.run()

        then:
        10 * someService.someMethod() >> {
            return counter.getAndIncrement() % 2 ? "SOME_VALUE" : null
        }

    }

    static interface SomeService {
        def someMethod()
    }

    static class SomeClass {
        private final SomeService someService

        SomeClass(SomeService someService) {
            this.someService = someService
        }

        void run() {
            (0..<10).each {
                def value = someService.someMethod()
                println "someService.someMethod() returned ${value}"
            }
        }
    }
}

---

希望有帮助。

可以使用链接：

10 * someService(_) >>> (1..10).collect {
       it % 2 ? SOME_VALUE : null
}

10 * someService(_) >>> (1..10).collect {
       it % 2 ? SOME_VALUE : null
}