Java 有一个简单的例子吗？

我想开始使用ANTLR，但在花了几个小时在站点上查看示例之后，我仍然无法清楚地理解Java过程的语法

---

有没有一些简单的例子，比如用ANTLR实现的四个运算计算器，它将遍历解析器定义并一直到Java源代码？

注意：这个答案适用于ANTLR3！如果您正在寻找一个ANTLR4示例，那么这将演示如何使用antl4创建一个简单的表达式解析器和计算器

---

首先创建一个语法。下面是一个小语法，可用于计算使用4个基本数学运算符构建的表达式：+、-、*和/。还可以使用括号对表达式进行分组

请注意，此语法只是一个非常基本的语法：它不处理一元运算符（1+9中的负数）或.99之类的小数（没有前导数），仅举两个缺点。这只是一个你可以自己动手的例子

下面是语法文件Exp.g的内容：

grammar Exp;

/* This will be the entry point of our parser. */
eval
    :    additionExp
    ;

/* Addition and subtraction have the lowest precedence. */
additionExp
    :    multiplyExp 
         ( '+' multiplyExp 
         | '-' multiplyExp
         )* 
    ;

/* Multiplication and division have a higher precedence. */
multiplyExp
    :    atomExp
         ( '*' atomExp 
         | '/' atomExp
         )* 
    ;

/* An expression atom is the smallest part of an expression: a number. Or 
   when we encounter parenthesis, we're making a recursive call back to the
   rule 'additionExp'. As you can see, an 'atomExp' has the highest precedence. */
atomExp
    :    Number
    |    '(' additionExp ')'
    ;

/* A number: can be an integer value, or a decimal value */
Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

/* We're going to ignore all white space characters */
WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

（解析器规则以小写字母开头，lexer规则以大写字母开头）

创建语法后，您需要从中生成解析器和词法分析器。下载并将其存储在与语法文件相同的目录中

在shell/命令提示符下执行以下命令：

java -cp antlr-3.2.jar org.antlr.Tool Exp.g

它不应该产生任何错误消息，现在应该生成文件ExpLexer.java、ExpParser.java和Exp.tokens

要查看其是否正常工作，请创建以下测试类：

import org.antlr.runtime.*；
公共类ANTLRDemo{
公共静态void main（字符串[]args）引发异常{
AntlStringStream in=新的AntlStringStream（“12*（5-6）”；
ExpLexer lexer=新的ExpLexer（in）；
CommonTokenStream令牌=新的CommonTokenStream（lexer）；
ExpParser=新的ExpParser（令牌）；
eval（）语法分析器；
}
}

并将其编译为：

// *nix/MacOS
javac -cp .:antlr-3.2.jar ANTLRDemo.java

// Windows
javac -cp .;antlr-3.2.jar ANTLRDemo.java

然后运行它：

// *nix/MacOS
java -cp .:antlr-3.2.jar ANTLRDemo

// Windows
java -cp .;antlr-3.2.jar ANTLRDemo

如果一切顺利，控制台将不会打印任何内容。这意味着解析器没有发现任何错误。当您将

“12*（5-6）”

更改为

“12*（5-6”

，然后重新编译并运行它时，应打印以下内容：

line 0:-1 mismatched input '<EOF>' expecting ')'

这不需要太多解释：每个规则都应该返回一个双精度值。现在要与返回值

双精度值

（不在普通Java代码块

{…}

）进行“交互”，您需要在

值

前面添加一个美元符号：

grammar Exp;

/* This will be the entry point of our parser. */
eval returns [double value]                                                  
    :    additionExp { /* plain code block! */ System.out.println("value equals: "+$value); }
    ;

// ...

以下是语法，但现在添加了Java代码：

grammar Exp;

eval returns [double value]
    :    exp=additionExp {$value = $exp.value;}
    ;

additionExp returns [double value]
    :    m1=multiplyExp       {$value =  $m1.value;} 
         ( '+' m2=multiplyExp {$value += $m2.value;} 
         | '-' m2=multiplyExp {$value -= $m2.value;}
         )* 
    ;

multiplyExp returns [double value]
    :    a1=atomExp       {$value =  $a1.value;}
         ( '*' a2=atomExp {$value *= $a2.value;} 
         | '/' a2=atomExp {$value /= $a2.value;}
         )* 
    ;

atomExp returns [double value]
    :    n=Number                {$value = Double.parseDouble($n.text);}
    |    '(' exp=additionExp ')' {$value = $exp.value;}
    ;

Number
    :    ('0'..'9')+ ('.' ('0'..'9')+)?
    ;

WS  
    :   (' ' | '\t' | '\r'| '\n') {$channel=HIDDEN;}
    ;

由于我们的

eval

规则现在返回一个double，请将您的ANTLRDemo.java更改为：

import org.antlr.runtime.*；
公共类ANTLRDemo{
公共静态void main（字符串[]args）引发异常{
AntlStringStream in=新的AntlStringStream（“12*（5-6）”；
ExpLexer lexer=新的ExpLexer（in）；
CommonTokenStream令牌=新的CommonTokenStream（lexer）；
ExpParser=新的ExpParser（令牌）；
System.out.println（parser.eval（））；//打印值
}
}

再次（重新）根据语法生成新的lexer和parser（1），编译所有类（2）并运行ANTLRDemo（3）：

现在您将看到表达式

12*（5-6）

的结果打印到您的控制台

再次强调：这是一个非常简短的解释。我鼓励你浏览并阅读一些教程和/或使用我刚刚发布的内容

祝你好运

编辑：

显示如何扩展上面的示例，以便可以提供一个

映射

，该映射在所提供的表达式中保存变量

---

要使此代码与当前版本的Antlr（2014年6月）一起工作，我需要做一些更改。

ANTLRStringStream

需要变成

AntlInputStream

，返回值需要从

parser.eval（）

更改为

parser.eval（）.value

，我需要删除末尾的

WS

子句，因为诸如

$channel

之类的属性值不再允许出现在lexer操作中。

对于Antlr 4，java代码生成过程如下所示：-

java -cp antlr-4.5.3-complete.jar org.antlr.v4.Tool Exp.g

相应地更新类路径中的jar名称。

在中，您将找到一个ANTLR java库，其中包含一些有用的帮助程序类和一些完整的示例。如果您喜欢eclipse和maven，它可以与maven一起使用

是一种简单的表达式语言，可以进行乘法和加法运算。 具有相应的单元测试

是一个IRI解析器，分为三部分：

语法分析器

词汇语法

基本语法

有针对它的单元测试

就我个人而言，我发现这是最棘手的一部分，要正确处理。参见

包含在早期版本中为ANTLR4的性能问题创建的另外三个示例。同时，此问题已被修复，如测试用例所示。

由Gabriele Tomassetti编写，非常有用

它有语法示例、不同语言（Java、JavaScript、C#和Python）的访问者示例以及许多其他内容。强烈推荐

编辑：Gabriele Tomassetti关于ANTLR的其他有用文章

---

版本4.7.1略有不同： 进口：

import org.antlr.v4.runtime.*;

对于主要部分-请注意以下内容：

CharStream in = CharStreams.fromString("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);

---

parser.eval（）

的实现发生在哪里？这在这里或ANTLR3 Wiki上都不清楚！@Jarrod，呃，对不起，我真的不明白你的意思。

eval

是一个解析器规则，它返回一个

double

。因此有一个

eval（）

方法您可以调用

ExpParser

的实例，正如我在

ANTLRDemo.main（…）

中演示的那样

import org.antlr.v4.runtime.*;

CharStream in = CharStreams.fromString("12*(5-6)");
ExpLexer lexer = new ExpLexer(in);
CommonTokenStream tokens = new CommonTokenStream(lexer);
ExpParser parser = new ExpParser(tokens);