如何在Grails中以JSON的形式返回特定的日期格式？

在Grails中，您可以使用JSON转换器在控制器中执行此操作：

render Book.list() as JSON

渲染结果为

[
{"id":1,
 "class":"Book",
 "author":"Stephen King",
 "releaseDate":'2007-04-06T00:00:00',
 "title":"The Shining"}
]

您可以通过在Config.groovy中进行设置来控制输出日期

grails.converters.json.date = 'javascript' // default or Javascript

然后结果将是一个本机javascript日期

[
{"id":1,
 "class":"Book",
 "author":"Stephen King",
 "releaseDate":new Date(1194127343161),
 "title":"The Shining"}
]

如果我想获得如下特定日期格式：

"releaseDate":"06-04-2007"

我必须使用“collect”，这需要大量键入：

return Book.list().collect(){
  [
      id:it.id,
      class:it.class,
      author:it.author,
      releaseDate:new java.text.SimpleDateFormat("dd-MM-yyyy").format(it.releaseDate),
      title:it.title
  ]
} as JSON

---

有更简单的方法吗？

有一个简单的解决方案：自从Grails 1.1以来，转换器被重写为更模块化的转换器。不幸的是，我没有完成这方面的文档。它现在允许注册所谓的ObjectMarshaller（实现

org.codehaus.groovy.grails.web.converters.marshaller.ObjectMarshaller

接口的简单Pogo/Pojo）

要实现所需的输出，可以通过以下方式在BootStrap.groovy中注册这样的ObjectMarshaller：

import grails.converters.JSON;

class BootStrap {

     def init = { servletContext ->
         JSON.registerObjectMarshaller(Date) {
            return it?.format("dd-MM-yyyy")
         }
     }
     def destroy = {
     }
}

---

还有其他几种方法可以自定义转换器的输出，我将尽我所能尽快赶上文档。

或者您可以在日期级别本身工作。这可能不是你想要的，但它可能会激发出一个解决方案的想法，该解决方案将在你的整个应用程序中始终如一地工作

def doWithDynamicMethods = {ctx ->

  def customDateToString = {->
        def dateFormat = "dd MMM yyyy"
        def timeFormat = "hh:mm:ss a"

        def timeCheck = new java.text.SimpleDateFormat("hh:mm:ss SSS a")
        def formattedTime = timeCheck.format(delegate)
        def formatString = dateFormat
        if (formattedTime != "12:00:00 000 AM") 
                              formatString = "$formatString $timeFormat"
        def formatter = new java.text.SimpleDateFormat("$formatString")
        formatter.format(delegate)
    }

    Date.metaClass.toString = customDateToString;
    java.sql.Timestamp.metaClass.toString = customDateToString;
}

---

当日期/时间戳实例转换为其JSON表示形式时，不会调用toString方法。干杯