Pine script 每日更改图表背景

有没有办法每天用不同的颜色来区分？例如，11月9日的图表背景颜色为红色，11月10日的图表背景颜色为绿色，等等，随着新的天数的增加，它们可以得到不同的颜色或重复的颜色模式？

漂亮的彩色问题：）
这应该能描绘出你在寻找什么

//@version=4
study("DayColors", overlay=true)

var color c0     = input(color.silver, "Sunday",    type=input.color)
var color c1     = input(color.red,    "Monday",    type=input.color)
var color c2     = input(color.orange, "Tuesday",   type=input.color)
var color c3     = input(color.yellow, "Wednesday", type=input.color)
var color c4     = input(color.green,  "Thursday",  type=input.color)
var color c5     = input(color.blue,   "Friday",    type=input.color)
var color c6     = input(color.purple, "Saturday",  type=input.color)
var int   transp = input(60, "Background transparancy", minval=0, maxval=100)

var arrColor     = array.new_color()

if barstate.isfirst
    array.push(arrColor, c0)
    array.push(arrColor, c1)
    array.push(arrColor, c2)
    array.push(arrColor, c3)
    array.push(arrColor, c4)
    array.push(arrColor, c5)
    array.push(arrColor, c6)

bgcolor(array.get(arrColor, dayofweek-1), transp)

编辑：根据评论中的要求，仅从市场开放到市场关闭应用颜色

//@version=4
study("DayColors", overlay=true)

var color c0       = input(color.silver, "Sunday",    type=input.color)
var color c1       = input(color.red,    "Monday",    type=input.color)
var color c2       = input(color.orange, "Tuesday",   type=input.color)
var color c3       = input(color.yellow, "Wednesday", type=input.color)
var color c4       = input(color.green,  "Thursday",  type=input.color)
var color c5       = input(color.blue,   "Friday",    type=input.color)
var color c6       = input(color.purple, "Saturday",  type=input.color)
var int   transp   = input(60, "Background transparancy", minval=0, maxval=100)
var       sess     = input("1800-1700:12345", "Session", type=input.session) // Asia session Monday to Friday
var       arrColor = array.new_color()
var int   t        = na

if barstate.isfirst
    array.push(arrColor, c0)
    array.push(arrColor, c1)
    array.push(arrColor, c2)
    array.push(arrColor, c3)
    array.push(arrColor, c4)
    array.push(arrColor, c5)
    array.push(arrColor, c6)

t := time(timeframe.period, sess)

bgcolor(na(t) ? na : array.get(arrColor, dayofweek-1), transp)

---

谢谢，这太好了。从市场开放到市场关闭，有没有办法做到这一点？（时间：下午6点到5点）我添加了一个代码示例，用于在特定时间之间应用颜色。这些小时数可以修改（输入）。