Vba 将数据粘贴到新工作表

我是VBA新手，所以我可能会问一些非常基本的问题-对不起！ 我有一个包含一系列记录的工作表，我想将这些记录移到另一个名为“七月档案”的工作表中。我正在使用这段代码，我知道这将覆盖“July Archive”中的目标单元格。但是我得到一个错误，说pasteValue操作失败了

另外，如何附加单元格而不是覆盖单元格。我尝试粘贴append，但出现一个错误，即对象不支持它

Sub Selectweeklyreport()

    ActiveSheet.Range("a16", ActiveSheet.Range("f16").End(xlDown)).Cut
    ActiveSheet.Goto ("July Archive")
    Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _
    False, Transpose:=False

End Sub

像这样

Sub Selectweeklyreport()
    Dim wsI As Worksheet, wsO As Worksheet
    Dim lRow As Long

    '~~> Replace this with the relevant sheet name
    Set wsI = Sheets("Sheet1")
    Set wsO = Sheets("July Archive")

    With wsI
        '~~> Get the last Row in Sheet1
        lRow = .Range("F" & .Rows.Count).End(xlUp).Row

        '~~> Copy the range from Sheet1
        .Range("A16:F" & lRow).Copy 'and not .Cut????

        '~~> Get the next available row in July Archive
        lRow = wsO.Range("A" & wsO.Rows.Count).End(xlUp).Row + 1

        '~~> Paste Special Values
        wsO.Range("A" & lRow).PasteSpecial Paste:=xlValues, _
        Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    End With
End Sub