VBscript-读取多个注册表值

我很难让我的VBscript读取每个Firefox插件的版本号。这些插件位于

HKEY\u LOCAL\u MACHINE\SOFTWARE\MozillaPlugins

。每个都在一个单独的文件夹中，每个文件夹都包含一个键

Version

，其中包含我要查找的值（以使其更清晰）。我知道我需要使用wmi，但我想我需要一个循环来遍历每个文件夹。我用link来帮助我，但我一直迷路

---

如有任何帮助或进一步信息，将不胜感激。很抱歉，如果这个问题问得不好，我的脚本编写技能非常有限。如果是这样，请留下评论，我会尽力提供更多信息。

下次请尽可能少地发布您已经准备好的内容。 这是我刚写的剧本

on error resume next
dim aKeys, version
Const HKEY_CURRENT_USER = &H80000001, HKEY_LOCAL_MACHINE = &H80000002
set oShell    = WScript.CreateObject("WScript.Shell")
set objreg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
strKeyPath = "Software\MozillaPlugins"
'read subkeys in array aKeys
objreg.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, aKeys
for each subkey In aKeys
  'read from version key if available
  version = oShell.RegRead("HKEY_LOCAL_MACHINE\" & strKeyPath & "\" & subkey & "\version")
  if version = "" then
    'perhaps version info in keyname itself ?
    version = split(split(subkey,"version=")(1),",")(0)
  end if
  if version = "" then
    version = "no version info available"
  end if
  wscript.echo split(subkey,",")(0) & ": " & version
  version = ""
next

在我的系统上

@adobe.com/FlashPlayer: 10.0.45.2
@docu-track.com/PDF-XChange Viewer Plugin: 1.0
@java.com/JavaPlugin: 160_23
@Microsoft.com/NpCtrl: 4.1
@microsoft.com/WPF: 3.5
@tracker-software.com/PDF-XChange Viewer Plugin: 1.0
@View22/View22: 3.10.50
Adobe Reader: 10.1.0

---

谢谢你的回答，这是我一直在寻找的解决方案。我通常会包含我尝试过的代码，但在本例中它太差了，我决定不包含。