Xslt 将字符串拆分为不同的元素

我有带文本元素和子字符串的xml，可以通过模式§\d+匹配：

是否可以使用xslt-1.0将其转换为单独的元素：

<p>
  <xsl:text>text-one </xsl:text>
  <a href="/link#42>§42</a>
  <xsl:text> text-two</xsl:text>
</p>

---

此样式表满足您的需要，只要

空白可以作为段落编号的结束分隔符

它转变

<root>
    <item>text-one §42 text-two §45</item>
    <item>§50 text-three</item>
    <item>text-four</item>
</root>

进入

这两个模板递归地相互调用，这对于XSL来说非常典型 标记化模板根据段落符号将内容拆分为符号前/后的开头和结尾 buildParagraphAnchor根据空格再次将尾部拆分为头部和尾部 这样，我们就能够将块放入正确的元素中 当段落符号是第一个字符等时，其余部分是特殊处理

---

因此，它将itemcontent分割成块，并将部分放入所需的元素。

如果您确实想使用基于正则表达式的匹配或分割，请检查您使用的XSLT 1处理器是否通过扩展函数支持这一点。

<xsl:template match="/">
    <root>
        <xsl:apply-templates select="root/*"/>
    </root>
</xsl:template>

<xsl:template match="item">
    <p>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="."/>
        </xsl:call-template>
    </p>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:choose>
        <xsl:when test="contains($text, '§')">
            <xsl:if test="substring-before($text, '§') != ''">
                <text><xsl:value-of select="substring-before($text, '§')"/></text>
            </xsl:if>
            <xsl:call-template name="buildParagraphAnchor">
                <xsl:with-param name="tail" select="substring-after($text, '§')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <text><xsl:value-of select="$text"/></text>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template name="buildParagraphAnchor">
    <xsl:param name="tail"/>
    <xsl:variable name="paragraphNumber">
        <xsl:choose>
            <xsl:when test="contains($tail, ' ')">
                <xsl:value-of select="substring-before($tail, ' ')"/>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$tail"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <a href="/link#{$paragraphNumber}"><xsl:text>§</xsl:text><xsl:value-of select="$paragraphNumber"/></a>
    <xsl:if test="contains($tail, ' ')">
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="concat(' ', substring-after($tail, ' '))"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

<root>
    <item>text-one §42 text-two §45</item>
    <item>§50 text-three</item>
    <item>text-four</item>
</root>

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <p>
        <text>text-one </text>
        <a href="/link#42">§42</a>
        <text> text-two </text>
        <a href="/link#45">§45</a>
    </p>
    <p>
        <a href="/link#50">§50</a>
        <text> text-three</text>
    </p>
    <p>
        <text>text-four</text>
    </p>
</root>