如何在vb.net中打印带有表头的datagridview表格？

我正在开发的系统中创建一个打印预览函数，它将预览我想要打印的datagridview。我使用ooopsoft作为参考，除了一个小问题外，它工作正常

问题:

在中，您可以看到序列号为1的dgv行丢失。标题似乎覆盖了第一行。我试过无数种方法来解决它，但我仍然找不到解决办法。我尝试退出“打印预览”对话框并再次打开它，但结果是。我想我遗漏了一行代码，但我不知道是什么。请提供帮助。

这是一个很好的开始，但存在一些错误和低效：

• 它使用

  newpage

  标志打印页眉或有新页面时打印第一行。很明显，你真的希望两者兼得
• 每页打印一次列标题，因此根本不需要在数据打印循环中
• 它不允许不可见的列或非默认对齐的列，您可能需要考虑其他此类设置
• 因为它实际上并没有打印正确的行数，所以一旦修复，您会发现它会将上一页的最后一行作为新页的第一行重新打印
• 有一个内部边沟或边距，这样文本就不会打印得太靠近网格线-这只是使用了1或2的偏移量
• 它还不必要地使用了

  single

  和

  RectangleF

• 也不准备再次显示或打印文档。您还需要在按钮单击或

  BeginPrint

  事件中重置

  mRow

  和

  newpage

我添加了一些注释，并给标题行着色，演示了如何实现

RowPrePaint

规则

Private mRow As Integer = 0
Private newpage As Boolean = True

Private Sub PrintDocument1_PrintPage(sender As System.Object,
                    e As PrintPageEventArgs) Handles PrintDocument1.PrintPage

    ' sets it to show '...' for long text
    Dim fmt As StringFormat = New StringFormat(StringFormatFlags.LineLimit)
    fmt.LineAlignment = StringAlignment.Center
    fmt.Trimming = StringTrimming.EllipsisCharacter
    Dim y As Int32 = e.MarginBounds.Top
    Dim rc As Rectangle
    Dim x As Int32
    Dim h As Int32 = 0
    Dim row As DataGridViewRow

    ' print the header text for a new page
    '   use a grey bg just like the control
    If newpage Then
        row = dgvZZ.Rows(mRow)
        x = e.MarginBounds.Left
        For Each cell As DataGridViewCell In row.Cells
            ' since we are printing the control's view,
            ' skip invidible columns
            If cell.Visible Then
                rc = New Rectangle(x, y, cell.Size.Width, cell.Size.Height)

                e.Graphics.FillRectangle(Brushes.LightGray, rc)
                e.Graphics.DrawRectangle(Pens.Black, rc)

                ' reused in the data pront - should be a function
                Select Case dgvZZ.Columns(cell.ColumnIndex).DefaultCellStyle.Alignment
                    Case DataGridViewContentAlignment.BottomRight,
                         DataGridViewContentAlignment.MiddleRight
                        fmt.Alignment = StringAlignment.Far
                        rc.Offset(-1, 0)
                    Case DataGridViewContentAlignment.BottomCenter,
                        DataGridViewContentAlignment.MiddleCenter
                        fmt.Alignment = StringAlignment.Center
                    Case Else
                        fmt.Alignment = StringAlignment.Near
                        rc.Offset(2, 0)
                End Select

                e.Graphics.DrawString(dgvZZ.Columns(cell.ColumnIndex).HeaderText,
                                            dgvZZ.Font, Brushes.Black, rc, fmt)
                x += rc.Width
                h = Math.Max(h, rc.Height)
            End If
        Next
        y += h

    End If
    newpage = False

    ' now print the data for each row
    Dim thisNDX As Int32
    For thisNDX = mRow To dgvZZ.RowCount - 1
        ' no need to try to print the new row
        If dgvZZ.Rows(thisNDX).IsNewRow Then Exit For

        row = dgvZZ.Rows(thisNDX)
        x = e.MarginBounds.Left
        h = 0

        ' reset X for data
        x = e.MarginBounds.Left

        ' print the data
        For Each cell As DataGridViewCell In row.Cells
            If cell.Visible Then
                rc = New Rectangle(x, y, cell.Size.Width, cell.Size.Height)

                ' SAMPLE CODE: How To 
                ' up a RowPrePaint rule
                'If Convert.ToDecimal(row.Cells(5).Value) < 9.99 Then
                '    Using br As New SolidBrush(Color.MistyRose)
                '        e.Graphics.FillRectangle(br, rc)
                '    End Using
                'End If

                e.Graphics.DrawRectangle(Pens.Black, rc)

                Select Case dgvZZ.Columns(cell.ColumnIndex).DefaultCellStyle.Alignment
                    Case DataGridViewContentAlignment.BottomRight,
                         DataGridViewContentAlignment.MiddleRight
                        fmt.Alignment = StringAlignment.Far
                        rc.Offset(-1, 0)
                    Case DataGridViewContentAlignment.BottomCenter,
                        DataGridViewContentAlignment.MiddleCenter
                        fmt.Alignment = StringAlignment.Center
                    Case Else
                        fmt.Alignment = StringAlignment.Near
                        rc.Offset(2, 0)
                End Select

                e.Graphics.DrawString(cell.FormattedValue.ToString(),
                                      dgvZZ.Font, Brushes.Black, rc, fmt)

                x += rc.Width
                h = Math.Max(h, rc.Height)
            End If

        Next
        y += h
        ' next row to print
        mRow = thisNDX + 1

        If y + h > e.MarginBounds.Bottom Then
            e.HasMorePages = True
            ' mRow -= 1   causes last row to rePrint on next page
            newpage = True
            Return
        End If
    Next


End Sub

---

预览后，

mRow

变量将指示所有行都已打印。如果用户单击“打印”或返回进行另一次预览，则不会打印任何内容。此代码还会重置要显示的第一页和初始缩放。

我建议您尝试使用数据集，我假设您只想获得输出。也许您可以尝试按报表表中的每行绑定datatable中的每个数据。它会自动为每个打印的数据字段创建一个标题。错误在于每个单元格的

循环。您可以看到，如果它是
（newpage）
，它将打印标题，或者打印第一行数据。你需要它两者兼而有之；打印新页的页眉，然后打印第一行。只需将newpage代码放入自己的循环中即可。@gnmerca您是说使用Microsoft报表查看器吗？我已经尝试过了，但是我遇到了一个异常
无法将sql datetime值转换为system.datetime
。它看起来还会将每页的最后一行复制为下一页的第一行page@Plutonix我不认为把每一页的最后一行复制到下一页的第一行。在我现在的打印预览中，它从第39行转到第40行，没有任何重复。
Private Sub PrintDocument1_BeginPrint(sender As Object, 
          e As PrintEventArgs) Handles PrintDocument1.BeginPrint
    mRow = 0
    newpage = True
    PrintPreviewDialog1.PrintPreviewControl.StartPage = 0
    PrintPreviewDialog1.PrintPreviewControl.Zoom = 1.0
End Sub