Abap 如何将小计按钮添加到集成数据访问（ALV with IDA）工具栏报告？

我想在集成数据访问ALV和IDA工具栏报告中添加小计按钮。与SALV的功能类似。我还附上了图片

---

此按钮已存在，您需要完成以下要求：

至少有一个总计列。 至少一个已排序列。 更多详细信息请参见博客文章和

工作示例示例：

CLASS lcl_alv DEFINITION.
  PUBLIC SECTION.
    METHODS:
      generate_alv.
  PRIVATE SECTION.
    DATA: o_salv_ida TYPE REF TO if_salv_gui_table_ida.
ENDCLASS.


START-OF-SELECTION.
  NEW lcl_alv( )->generate_alv( ).

CLASS lcl_alv IMPLEMENTATION.
  METHOD generate_alv.
    o_salv_ida = cl_salv_gui_table_ida=>create( iv_table_name = 'SBOOK' ).

    DATA(lo_layout) = o_salv_ida->default_layout( ).
    DATA(lt_sort_rule) = VALUE if_salv_gui_types_ida=>yt_sort_rule(
                       ( field_name = 'FLDATE'
                         descending = abap_false
                         is_grouped = abap_true ) ).
    lo_layout->set_sort_order( it_sort_order = lt_sort_rule ).

    DATA(lt_aggr_rules) = VALUE if_salv_gui_types_ida=>yt_aggregation_rule(
                       ( field_name = 'LUGGWEIGHT'
                         function   = if_salv_service_types=>cs_function_code-sum ) ).
    lo_layout->set_aggregations( lt_aggr_rules ).

    o_salv_ida->fullscreen( )->display( ).

  ENDMETHOD.
ENDCLASS.

---

我看过热情洋溢。这些例子与SALV有关。我正在寻找集成数据访问的ALV解决方案。工作示例非常有助于理解。