Actionscript 3 需要帮助了解Actionscript 3 AS3中的MVC实现吗

我正在学习使用ActionScript 3.0实现MVC。到目前为止，我做得还不错，但有几个问题可以让我的学习过程非常愉快。我将非常感谢你的帮助和智慧

让我解释一下我是如何实现一个简单的MVC实现的：

我的Flash电影叫FusionMVC。我将所有MVC文件放在同一个包中，如下所示：

数据模型 数据控制 数据视图 应用程序外观

我的问题是：

正如我正确理解的，每当我需要在主舞台上放置一个显示对象时，我都会在DataView类中声明或实现该显示对象，对吗

我在主库中有一个名为“Box”的符号/显示对象。我通过在运行时可以看到的DataView类中实例化该符号，将其添加到stage中。现在，如果需要将名为“ClickHandler”的EventListener添加到此对象：

我在哪里声明这个“ClickHandler”事件？我目前正在DataModel类中声明它

我感到困惑的是在哪里声明EventHandler方法。数据模型，还是数据控制

谢谢你的帮助。以下是完整的代码：

//DATAMODEL

package
{
    import flash.events.*;
    import flash.errors.*;

    public class DataModel extends EventDispatcher
    {
        public static const UPDATE:String = "modelUpdaed";
        private var _txt:String;

        public function DataModel()
        {

        }

        public function get Text():String
        {
            return _txt;
        }

        public function set Text(p:String):void
        {
            _txt = p;
            notifyObserver();
            trace("MODEL HAS BEEN CHANGED");
        }

        public function notifyObserver():void
        {
            dispatchEvent(new Event(DataModel.UPDATE));
        }

        public function sayHello(e:Event):void
        {
            trace("HEY HELLO");
        }

    }
}

//DATACONTROL

package
{
    import flash.display.*;
    import flash.events.*;
    import flash.errors.*;

    public class DataControl
    {
        private var _model:DataModel;

        public function DataControl(m:DataModel)
        {
            _model = m;
        }


    }
}

//DATAVIEW

package
{
    import flash.display.*;
    import flash.events.*;
    import flash.errors.*;

    public class DataView extends Sprite
    {
        private var _model:DataModel;
        private var _control:DataControl;
        public var b:Box;

        public function DataView(m:DataModel, c:DataControl)
        {
            _model = m;
            _control = c;

            addBox();
        }

        public function addBox():void
        {
            b = new Box();
            b.x = b.y = 150;
            //b.addEventListener(MouseEvent.CLICK, vHandler);
            addChild(b);
        }


    }
}

//APPLICATION FACADE

package 
{
    import flash.display.*;
    import flash.events.*;
    import flash.errors.*;

    public class Main extends Sprite
    {
        private var _model:DataModel;
        private var _control:DataControl;
        private var _view:DataView;

        public function Main()
        {
            _model = new DataModel();
            _control = new DataControl(_model);
            _view = new DataView(_model, _control);

            addChild(_view);
        }
    }
}

---

您是正确的-显示对象应处理来自其子对象的事件：

public function addBox():void
    {
        b = new Box();
        b.x = b.y = 150;
        b.addEventListener(MouseEvent.CLICK, boxClickHandler);
        addChild(b);
    }

在视图中处理事件：

private function boxClickHandler(event:MouseEvent)
{
    _control.sayHello();
}

然后，您只需向控制器添加更改模型的方法：

public class DataControl
{
....
public function sayHello():void
{
    _model.sayHello();
}