Command line 批处理文件不断重置为开始

我打算使用下面的代码关闭或重新启动计算机。每次我运行此脚本时，它都会返回到

set/p var=Type computer name here:

您能告诉我，我的脚本有什么问题，以及如何修复它吗

@ECHO off
set /p var=Type computer name here: 
cls
TITLE %var% power control!!!!
ECHO Copyright © Joshua Reynolds 2012
ECHO USE THIS PROGRAM AT YOUR OWN RISK
pause
:start
cls
ECHO Choose an option below:
ECHO 1. Shutdown
ECHO 2. Restart
ECHO 3. Abort previous choice
ECHO 4. Exit
set /p choice=Type the options number: 
if not '%choice%'=='' set choice=%choice:~0,1%
if '%choice%'=='1' goto shutdown
if '%choice%'=='2' goto restart
if '%choice%'=='3' goto abort
if '%choice%'=='4' exit
cls
ECHO "%choice%" is not a valid option please try again
ECHO.
pause
goto start
:shutdown
COLOR 4f
cls
ECHO To shutdown %var%
pause
shutdown /s /m \\%var%
ECHO %var% should now shutdown.
goto start
:restart
COLOR A0
cls
ECHO To restart %var%
pause
shutdown /r /m \\%var%
ECHO %var% should now restart.
goto end
:abort
COLOR 5f
cls
shutdown /a /m \\%var%
goto end
:end
pause
COLOR 0f
goto start

---

批处理脚本的名称可能是shutdown.bat，它位于当前目录中。因此，当脚本尝试运行SHUTDOWN命令时，它会重新运行批处理脚本

---

您可以更改脚本的名称，也可以在需要调用命令时在脚本中显式使用

shutdown.exe

。

那里有足够的回声。从哪里开始，它不断地回到批次的顶部？帮助我们，帮助你。你需要给出问题的全部细节，并在试图解决问题时发布。否则，您可能会得到与您已经做过的相同的答案。尝试自己解决问题也是礼貌的。@JoshuaReynolds-如果这个答案解决了你的问题，那么你应该点击左上角附近的复选标记来接受答案。这个动作让其他人知道问题已经得到了回答，它会给你2分，给回答者15分。每个问题只能接受一个答案。一旦你得到15分，你将有权对任何你认为有用的答案进行投票，包括对其他人问题的答案。投票结果表明，答案为10分。