Dynamic 处理连接表键的通用方法

如果我有一个tabkey值，例如DATAlv_tabkey='1000041508773180000013000'，它是一个条目的所有表键的连接值，我知道相应表的名称：

我如何才能在不手动拆分tabkey的情况下获取表项，从而不必写入每个键字段的顺序和长度

完整示例：

" The first 3 chars always belong to the 'mandt' field 
" which can't be filtered in the SELECT, therefore 
" I ignore it and start with key2
DATA(lv_tabkey) = '1000041508773180000013000'.

"ToDo - how to make this generic? - START
DATA(lv_key2) = lv_tabkey+3(12).
DATA(lv_key3) = lv_tabkey+15(3).
DATA(lv_key4) = lv_tabkey+18(4).
DATA(lv_key5) = lv_tabkey+22(3).
DATA(lv_where) =      'key2 = ' && lv_key2 && 
                 ' AND key3 = ' && lv_key3 && 
                 ' AND key4 = ' && lv_key4 && 
                 ' AND key5 = ' && lv_key5.
"ToDo - how to make this generic? - END

SELECT *
  FROM table_x
  INTO TABLE DATA(lt_results)
  WHERE (lv_where).

---

我想我必须以某种方式迭代表字段，找出键及其长度，但我不知道如何做到这一点。

您的用例提醒我如何处理更改文档键。CDHDR/CDPOS。 希望有帮助

DATA:
  lv_tabkey  TYPE char50,
  ls_table   TYPE table_x.
FIELD-SYMBOLS:
  <ls_src_x> TYPE x,
  <ls_tgt_x> TYPE x.

"Add Client info the Table key if your table is Client dependent. 
CONCATENATE sy-mandt lv_tabkey INTO lv_tabkey.

ASSIGN lv_tab_key TO <ls_src_x> CASTING.
ASSIGN ls_table TO <ls_tgt_x> CASTING.
<ls_tgt_x> = <ls_src_x>.

"Now ls_table has the key info filled including MANDT if you have the MANDT in table key. 

SELECT *
  FROM table_x
    INTO TABLE DATA(lt_results)
    WHERE key2 = ls_table-key2 AND key3 = ls_table-key3
          AND key4 = ls_table-key4 AND key5 = ls_table_key5.

---

您寻求的声明是：

将tabkey指定给强制类型句柄r\u TYPE\u struct

了解表键结构的类型句柄后，可以以通用方式用值填充它，并使用该结构查询表。以下是如何：

DATA: handle      TYPE REF TO data,
      lref_struct TYPE REF TO cl_abap_structdescr.

FIELD-SYMBOLS: <key_fld> TYPE abap_componentdescr.

SELECT * UP TO 5000 ROWS
  FROM cdpos
  INTO TABLE @DATA(t_cdpos)
  WHERE tabname NOT LIKE '/%'.

LOOP AT t_cdpos ASSIGNING FIELD-SYMBOL(<fs_cdpos>).
  lref_struct ?= cl_abap_structdescr=>describe_by_name( <fs_cdpos>-tabname ).

* get key fields
  DATA(key_fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) WHERE ( keyflag NE space ) ( line ) ).

* filling key field components
  DATA(key_table) = VALUE abap_component_tab( FOR ls_key IN key_fields
                                              ( name = ls_key-fieldname
                                                type = CAST #( cl_abap_datadescr=>describe_by_name( ls_key-domname ) )
                                               )
                                            ).
* create key fields type handle
  TRY.
      DATA(r_type_struct) = cl_abap_structdescr=>create( key_table ).
    CATCH cx_sy_struct_creation .
  ENDTRY.

* create key type
  CHECK r_type_struct IS NOT INITIAL.
  CREATE DATA handle TYPE HANDLE r_type_struct.
  ASSIGN handle->* TO FIELD-SYMBOL(<structure>).

* assigning final key structure
  ASSIGN <fs_cdpos>-tabkey TO <structure> CASTING TYPE HANDLE r_type_struct.

* filling values
  LOOP AT key_table ASSIGNING <key_fld>.
    ASSIGN COMPONENT <key_fld>-name OF STRUCTURE <structure> TO FIELD-SYMBOL(<val>).
    CHECK sy-subrc = 0.
    <key_fld>-suffix = <val>.
  ENDLOOP.

  DATA(where_cond) = REDUCE string( INIT where = ` ` FOR <field> IN key_table WHERE ( name <> 'MANDT' ) NEXT where = where && <field>-name && ` = '` && <field>-suffix && `' AND ` ).
  where_cond = substring( val = where_cond off = 0 len = strlen( where_cond ) - 4 ).

  IF <fs_cdpos>-tabname = 'BNKA'.
    SELECT *
    INTO TABLE @DATA(lt_bnka)
    FROM bnka
    WHERE (where_cond).
  ENDIF.

ENDLOOP.

在这里，我在表CDPOS上构建了一个示例，该表包含表名和字段tabkey中额外连接的键值，换句话说，这正是您试图使用的

在循环中，它检测表类型，构建键，并以通用方式进行SQL查询。为了简单起见，我在这里使用了表BNKA，但也可以通过字段符号来泛化SQL SELECT。我还做了一个技巧，在后缀字段中将值填充到包含结构组件的同一个选项卡中

---

另外，在将where条件传递到查询中之前，请进行适当的数据类型验证，以避免此类错误，例如，由于使用新语法，它会进行严格的检查。

除非是Z表，否则您是否可以发布实际尝试访问的表？我认为您需要的是将tabkey存储为单个字段的表连接起来，这样您就可以在不拆分的情况下从表_x中进行选择。如何使其通用？不可能。您始终需要知道表结构、字段长度以及用于键的字段集。只有使用这3个参数和RTT，您才能构造用于解析密钥的通用方法。@Suncatcher那么我不知道正确的措辞-可能是动态的？我的意思是不必手动执行代码中的“+184”-操作，但这个问题是关于对任何表执行这些操作的，这就是为什么实际的表应该不重要的原因-因此，除非table_x也有一个tabkey字段，否则我看不出联接可以做什么，如果表格没有共同的唯一字段，请编辑您的问题：添加一个示例，因为人们不理解您的意思。哇，我没想到会有那么难-但这正是我一直在寻找的，效果很好-谢谢！！！