Eclipse为多种语言设置 我在各种学校项目中使用了Eclipse平台，用于java、javaEE、C++、python和php。现在我对它有点熟悉了，我想要一些关于如何设置它的更准确的说明。我在windows7上-我已经在我的Dropbox中删除了eclipse本身，并根据需要创建了工作区，但这最终导致了设置的混乱，到处都是，并出现了各种错误（当我尝试更新到Juno时出现了这些错误-现在的功能如）

那么，为各种语言设置eclipse的推荐方法是什么呢？我应该吗

---

下载最新版本，添加我需要的插件（cdt、pdt等），然后为不同的语言创建不同的工作区（如eclipse\u python、eclipse\u java、eclipse\u javaEE等）？如何设置Eclipse？

我已经密集使用Eclipse大约6年了，我建议为最多1或2种不同的编程语言设置单独的Eclipse安装。原因是，如果插件太多，eclipse可能会消耗太多内存或处理器时间（当然，这取决于插件在后台所做的工作等等），这可能会导致UI没有响应

我还建议为每个eclipse安装使用单独的工作区，以便不同的配置/安装不会相互干扰

我写了一个小命令行脚本，它允许我切换工作区中的.metadata目录，以便与便携式驱动器一起使用（支持两种模式：home和portable），也许有人会觉得这很有用

@ECHO OFF

REM This Script is used to ease using eclipse in a portable manner
REM The script allows to easily switch between several workspace metadata

REM arg1: eclipse runnable
REM arg2: workspace dir
REM arg3: metadata mode (portable or home)

:CHECK_ARG_ONE
IF %1 == "" GOTO :HELP
IF /i %1 == "/h" GOTO :HELP
IF /i %1 == "/?" GOTO :HELP
IF /i %1 == "/help" GOTO :HELP
IF /i %1 == "-h" GOTO :HELP
IF /i %1 == "-?" GOTO :HELP
IF /i %1 == "-help" GOTO :HELP
IF /i %1 == "--h" GOTO :HELP
IF /i %1 == "--?" GOTO :HELP
IF /i %1 == "--help" GOTO :HELP


:CHECK_ARG_TWO
IF %2 == "" GOTO :ERROR_ARG_TWO


:CHECK_ARG_THREE
IF %3 == "" GOTO :ERROR_ARG_THREE


:PREPARE
SET "ECLIPSE_RUNNABLE=%1"
SET "WORKSPACE_DIR=%2"
ECHO Working Dir: %CD%
ECHO Eclipse Runnable: %ECLIPSE_RUNNABLE%
ECHO Workspace Dir: %WORKSPACE_DIR%
SET "MD=.metadata"
SET "MD_HOME=.metadata_home"
SET "MD_PORTABLE=.metadata_portable"
PUSHD %WORKSPACE_DIR%
IF /i %3 == home GOTO :HOME
IF /i %3 == portable GOTO :PORTABLE
GOTO :ERROR_ARG_THREE_WRONG


:HOME
ECHO Starting home version
IF EXIST %MD% (
    IF EXIST %MD_HOME% (
        IF EXIST %MD_PORTABLE% (
            GOTO :ERROR_MD_PORTABLE_EXISTS_ALREADY
        ) ELSE (
            REN %MD% %MD_PORTABLE%
            REN %MD_HOME% %MD%
        )
    )
) ELSE (
    IF NOT EXIST %MD_HOME% (
        GOTO :ERROR_MD_HOME_EXISTS_NOT
    ) ELSE (
        REN %MD_HOME% %MD%
    )
)
GOTO :RUN


:PORTABLE
ECHO Starting portable version
IF EXIST "%MD%" (
    IF EXIST "%MD_PORTABLE%" (
        IF EXIST "%MD_HOME%" (
            GOTO :ERROR_MD_HOME_EXISTS_ALREADY
        ) ELSE (
            REN "%MD%" %MD_HOME%
            REN "%MD_PORTABLE%" %MD%
        )
    )
) ELSE (
    IF NOT EXIST "%MD_PORTABLE%" (
        GOTO :ERROR_MD_PORTABLE_EXISTS_NOT
    ) ELSE (
        REN "%MD_PORTABLE%" %MD%
    )
)
GOTO :RUN


:ERROR_ARG_TWO
ECHO No second argument supplied (workspace dir)
GOTO :END_ERROR


:ERROR_ARG_THREE
ECHO No third argument supplied (metadata mode - home ^| portable)
GOTO :END_ERROR


:ERROR_ARG_THREE_WRONG
ECHO Supplied third argument (metadata mode) must match (home ^| portable)
GOTO :HELP


:ERROR_MD_HOME_EXISTS_ALREADY
ECHO Trying to rename "%MD%", but the metadata directory "%MD_HOME%" already exists!
GOTO :END_ERROR


:ERROR_MD_HOME_EXISTS_NOT
ECHO Neither "%MD%" nor "%MD_HOME%" exist!
GOTO :END_ERROR


:ERROR_MD_PORTABLE_EXISTS_ALREADY
ECHO Trying to rename "%MD%", but the metadata directory "%MD_PORTABLE%" already exists!
GOTO :END_ERROR


:ERROR_MD_PORTABLE_EXISTS_NOT
ECHO Neither "%MD%" nor "%MD_PORTABLE%" exist!
GOTO :END_ERROR


:HELP
ECHO.
ECHO Eclipse starter script to switch between home and portable metadata
ECHO ©Till Kolditz 2011 (till.kolditz@googlemail.com)
ECHO.
ECHO This Script is used to ease using eclipse in a portable manner.
ECHO It allows to easily switch between portable and "home" or stationary
ECHO workspace metadata.
ECHO.
ECHO Usage: run.bat (eclipse_runnable) (workspace_dir) (home ^| portable)
ECHO.
ECHO Example1: run.bat eclipse\eclipse.exe workspace home
ECHO Example2: run.bat "eclipse (x64)\eclipse.exe" workspace_special portable
GOTO :END


:RUN
POPD
START "Eclipse" %ECLIPSE_RUNNABLE% -data %WORKSPACE_DIR%
GOTO :END


:END_ERROR
POPD
REM PAUSE for debugging
PAUSE
GOTO :END


:END
GOTO :EOF

---

所以你的意思是说最好在单独的目录中下载EclipseCDT和EclipseJavaEE等，然后启动所需的目录？您的脚本还用于使用不同的元数据文件夹（即不同的工作区）运行各种eclipse安装？我不确定我在1）是的2）我写这个脚本是因为我在SSD上有我的开发工具（eclipses）并每天把它带到大学-驱动器号不能和我在家插SSD时一样。因此，每次我将SSD用作便携式驱动器时，任何绝对路径（例如构建路径变量）都会发生变化。我的诀窍是拥有2个不同的元数据文件夹，每次选择一个合适的文件夹。因此，在设置所有必要设置的情况下创建一次工作区。然后复制整个.metadata文件夹并将其命名为“.metadata\u-portable”。好的-我可能会离开，因此我可能不会及时响应-然后你必须同步元数据和metadata\u-portable-或者不同步？我在编写脚本时没有考虑到这一点。使用我的脚本，您必须分别在便携版或家用版中进行更改（这会导致元数据更改）。但是，您可以创建第三个元数据文件夹（例如，metadata_base），并在其他两个元数据文件夹（home/portable）内创建硬链接，将其链接到此基本文件夹，以便对home/portable设置相同