Excel 如何在多张图纸上插入月/年？

我想将上个月的月份和年份添加到多张表的A2中，而不选择每个单独的表。我正在设置一个模板，每月运行报告

我已经搜索过了，但我找不到类似的示例，而是选择了每个表

Sub dateins()
' Date as Mo and year. Current month minus one.
Dim dash As Worksheet, daily As Worksheet, mon As Worksheet
Dim Thisday As Date, Rptmon As Date, ws As Worksheet

Set dash = Sheets("Dashboard")
Set daily = Sheets("Daily")
Set mon = Sheets("Monthly")
Thisday = Date

Rptmon = DateAdd("m", -1, Thisday)
Rptmon = Format(Thisday, "mmmm yyyy")
   For Each ws In ThisWorkbook.Sheets
    Select Case ws.Name
     Case "dash", "daily", "mon"
        If ws.Range("A2") = "" Then
            ws.Range("A2").Replace What:="", Replacement:=Rptmon
        End If
   End Select
  Next ws

End Sub

---

此循环不会在任何图纸上插入日期。谢谢你的帮助

您的选择案例查看的是工作表名称，而不是分配给工作表对象的变量

Sub dateins()

    ' Date as Mo and year. Current month minus one.
    Dim dash As Worksheet, daily As Worksheet, mon As Worksheet
    Dim Thisday As Date, Rptmon As Date, ws As Worksheet

    Set dash = Sheets("Dashboard")
    Set daily = Sheets("Daily")
    Set mon = Sheets("Monthly")
    Thisday = Date

    Rptmon = DateAdd("m", -1, Thisday)
       For Each ws In ThisWorkbook.Sheets
        Select Case ws.Name
          Case "Dashboard", "Daily", "Monthly"
            If ws.Range("A2") = "" Then
                ws.Range("A2") = Rptmon
                ws.Range("A2").numberformat = "mmmm yyyy"
            End If
       End Select
      Next ws

End Sub

---

您希望为A2指定一个真实日期，并让单元格格式显示“mmmm-yyyy”。

要将日期应用到的工作表的区分大小写的全名是什么？“Dashboard”、“Daily”、“Monthly”我改为区分大小写的全名，效果非常好！谢谢你的简单更正。