Gnuplot 绘图

在视觉上，在一个框架中给出了两个不同的图形（布局1、2）。 两个图都受y0:7的约束

关于柱图（声子分布）“ZrSbTe.ph_THz”和xmax=0.885990的数据 关于第二列图形的数据为“ZrSbTe.dos_THz”和2:1（总计）、3:1（Zr）、4:1（Sb）和5:1（Te），即文件中第一列图形中的y轴，文件中的其他列作为图形中的x轴。 70%的面积用于第一张图表，30%的面积用于第二张图表。 让我们通过关注颜色来获得相同的图表。 让我们制作一个2页的PDF来加载gnuscript和输出图形

列标签的x坐标（指定y坐标）

Γ=-0.01
X=0.13
L=0.20
T=0.22
W=0.251
R=0.34
X1=0.38
Z=0.50
Γ = 0.575
Y=0.67
S=0.715
W=0.835

---

您的最终目标可能会被分成许多不同的问题和“如何做”…太多了，没有任何代码和特定的问题。请记住，对于每个关键字，您可以在gnuplot控制台中键入

help

，以获取一些信息。请查看gnuplot主页和本地文档文件夹中的PDF手册。 我假设您是gnuplot的新手……请检查以下示例作为起点。如果您有特定的问题，请记住：问题总是与代码一起出现

代码：

### split graph
reset session

$Labels <<EOD
Γ   -0.01
X    0.13
L    0.20
T    0.22
W    0.251
R    0.34
X1   0.38
Z    0.50
Γ    0.575
Y    0.67
S    0.715
W    0.835
EOD

# create some random test data
N=100
set print $PH
    do for [i=0:N] {
        print sprintf("%g %g %g %g %g",-0.01+i*(0.835+0.01)/N, rand(0)*3, rand(0)*3+1, rand(0)*3+3, rand(0)*3+4)
    }
set print $DOS
    print "X Total Zr Sb Te"
    do for [i=0:N] {
        print sprintf("%g %g %g %g %g",-0.01+i*(0.835+0.01)/N, rand(0), rand(0)+1, rand(0)+2, rand(0)+3)
    }
set print

# set lines
do for [i=1:|$Labels|] {
    set arrow i from word($Labels[i],2),graph 0 to word($Labels[i],2), graph 1 nohead lw 1.5 front
}

set ylabel "Frequency / THz"
set key noautotitle opaque box
set colorsequence classic

set multiplot layout 1,2

    set size 0.7,1
    set bmargin 3
    set rmargin 0
    plot for [i=2:5] $PH u 1:i w l lc "dark-grey", \
         $Labels u 2:(NaN):xtic(1)

    set size 0.3,1
    set origin 0.7,0
    set lmargin 0
    set rmargin -1
    unset ylabel
    unset tics
    unset arrow
    set xlabel "DOS"
    plot for [i=2:5] $DOS u i:1 w l ti columnhead(i)
unset multiplot
### end of code

拆分图 重置会话

---

$Labels欢迎来到StackOverflow！你有一些gnuplot代码吗？你的问题是什么？我不清楚。你是想创建一个多页PDF吗？请编辑你的问题并澄清。我需要按格式绘制两个数据（一个图形中有两个布局）如图所示：第一个是声子分布，其数据取自一个名为“ZrSbTe.ph_THz”的文件这里需要显示它的xmax，xmax=0.885990，我也需要像这样显示x坐标；Γ=-0.01 X=0.13 L=0.20 T=0.22 W=0.251 R=0.34 X1=0.38 Z=0.50Γ=0.575 Y=0.67 S=0.715 W=0.835对于第二个图形：我们需要像轴一样转换；X到Y，Y到X如图所示。数据将取自“ZrSbTe.dosΓTHz”，其数据列为：Γ=-0.01 X=0.13 L=0.20 T=0.22 W=0.251 R=0.34 X1=0.38 Z=0.50Γ=0.575 Y=0.67 S=0.715 W=0.835。对于第二个图形，我们需要转换类轴；X到Y，Y到X如图所示。数据将取自“ZrSbTe.dos_THz”，其数据列为：2:1（总计）、3:1（Zr）、4:1（Sb）ve 5:1（Te）。对于布局，第一个图形应占图形的70%，第二个图形应占30%。两个图形的y轴都约束为0.7。我可以上传数据文件，它们是“ZrSbTe.ph_TH”和“ZrSbTe.dos_TH”。有什么帮助吗？坦克你的代码是什么？到目前为止你试过什么？你走了多远？没有任何代码是有点太少的努力。StackOverflow不是一种编码服务，这里的人们期望自己的一些研究工作和一些最小的代码（即使/尤其是如果它不起作用或没有给出期望的结果）[yavuzhan@cluster~]$vi 05.gnu[yavuzhan@cluster~]$gnuplot 05.gnu重置会话^“05.gnu”，第2行：警告：预期可选轴名称重置会话^“05.gnu”，第2行：“；”expected@FatihYavuzhan你有什么操作系统和gnuplot版本？如何启动脚本？