是否在macOS搜索结果中隐藏重复文件？

我不想删除重复的文件，但我只想看到每个文件的一个实例

在这种情况下，重复项之间的优先级并不重要

///

实际情况：

我想创建一个VLC播放列表，其中包含我从特定域下载的所有视频。这些文件组织得不好，许多文件存在于我的计算机上的多个位置。因此，查找器搜索“Where from”-->[域]会返回许多重复的文件。这意味着我不能把搜索结果拖放到VLC中，而不存在许多重复项

我不想重复删除文件本身

---

如何做到这一点？

在查找器搜索中无法隐藏重复项，因为在查找器搜索中没有过滤重复项的选项

但你的工作是搜索，然后创建一个播放列表。这可以通过将您的选择拖放到下一个小水滴上来完成，您可以将其称为“VLC播放列表创建者”。（或者使用Automator将其转换为“制作VLC播放列表”服务）。它将为您过滤重复项并打开VLC.app的“保存播放列表”对话框

on open theAliases
    set {namesList, moviesList} to {{}, {}}
    repeat with i from 1 to count theAliases
        set anAlias to item i of theAliases
        tell application "Finder" to set theName to name of anAlias
        if not (namesList contains theName) then
            set end of namesList to theName
            set end of moviesList to anAlias
        end if
    end repeat
    -- try to restart "VLC" to clear old playlist
    if running of application "VLC" then quit application "VLC"
    repeat while running of application "VLC"
        delay 0.1
    end repeat
    -- add movies to playlist
    tell application "VLC"
        open moviesList
        stop
        activate
    end tell
    -- save playlist dialog
    tell application "System Events" to keystroke "s" using command down
    tell application "VLC" to activate
end open

---

您是如何搜索的？视频是否具有相同的名称？当视频是相同的文件时，它们具有相同的名称。我一直在使用“Where from”参数在Finder中搜索，源域作为我的搜索词。