Netlogo 除了X Y坐标，我如何查看导入的shapefile中存在的其他值/信息

我将一个shapefile加载到NetLogo中。 称为“地点”。 我可以在指挥中心查看XY坐标。但是，我想查看每个坐标的OBJECTID（显示在shapefile中）。我需要这些信息以供参考。

---

如何才能查看形状文件中每条线要素的OBJECTID？

在本示例设置中，“Sector_Boundary.shp”是一个包含10个子单元的形状文件：

extensions [ gis ]
globals [ example-gis-data ]

to setup
  ca
  set example-gis-data gis:load-dataset "Sector_Boundary.shp"
  gis:set-drawing-color white
  gis:draw example-gis-data 1
  reset-ticks  
end

如果只需要输出对象ID，可以使用

gis:feature list of

提取要素列表，然后使用

gis:property value

提取每个要素的“OBJECTID”：

to view-info
  let list-of-features gis:feature-list-of example-gis-data
  let list-of-ids map [ i -> gis:property-value i "OBJECTID" ] list-of-features
  print list-of-ids
end

当然，您可以根据需要对不同的属性名称执行相同的操作，并根据需要输出其他引用信息。例如，如果您的位置shapefile有一个名称字段，就像我的“Sector_Boundary.shp”一样，您可以执行以下操作：

to view-info
  let list-of-features gis:feature-list-of example-gis-data
  let list-of-ids map [ i -> gis:property-value i "OBJECTID" ] list-of-features
  let list-of-names map [ i -> gis:property-value i "NAME" ] list-of-features
  ( foreach list-of-names list-of-ids [
    [ name id ] ->
    print ( word "Name: " name ", Object id: " id )
  ])  
end

查看与每个对象id关联的名称

---

非常感谢你，卢克。你的指示很容易执行。@chief-没问题！如果该答案解决了您的问题，请单击其旁边的复选标记，将您的问题标记为已结束。