Pine script 每日均线自动调整

我有一个5均线指标，我想转换如下

我希望水平线自动对齐，我目前每天手动将其移动到当前EMA值（然后使EMA指示器不可见，以便只有H线可见）

我已经处理了几个现成的代码片段，但我就是找不到解决方案。我尝试了“24x7”，“00:00”和相应的命令等，但我没有得到它。我也不想看到前一天的台词。你知道我的意思吗？它应该会在00:00自动将我的H线移动到相应的EMA值。我已经在谷歌上搜索了很久了，但是作为一个初学者，我找不到任何可以使用的东西

//5 Horizontal EMA by -=Tre$aCo7n=-
//Modified from 4 Exponential Moving Averages from @vitastrato

study(title="5 Horizontal EMA", shorttitle="5 H. EMA", overlay=true)

len1 = input(10, minval=8, title="Length")
len2 = input(21, minval=8, title="Length")
len3 = input(55, minval=8, title="Length")
len4 = input(100, minval=8, title="Length")
len5 = input(200, minval=8, title="Length")

src = input(close, title="Source")

entryema = ema(src, len1)
fastema = ema(src, len2)
mediumema = ema(src, len3)
slowema = ema(src, len4)
veryslowema = ema(src, len5)

plot(entryema, color=green, linewidth=3, title="Entry EMA")
plot(fastema, color=orange, linewidth=3, title="Fast EMA")
plot(mediumema, color=red, linewidth=3, title="Medium EMA")
plot(slowema, color=white, linewidth=3, title="Slow EMA")
plot(veryslowema, color=purple, linewidth=3, title="Veryslow EMA")``` 

---

这将绘制出您需要的内容。
截止时间

00:00

以交换时间表示

//@version=4
//5 Horizontal EMA by -=Tre$aCo7n=-
//Modified from 4 Exponential Moving Averages from @vitastrato

study(title="5 Horizontal EMA", shorttitle="5 H. EMA", overlay=true)

len1 = input(10, minval=8, title="Length")
len2 = input(21, minval=8, title="Length")
len3 = input(55, minval=8, title="Length")
len4 = input(100, minval=8, title="Length")
len5 = input(200, minval=8, title="Length")
src  = input(close, title="Source")

var bool show_hlines = input(true, "Show horizontal lines", input.bool)
var bool show_emas   = not show_hlines

var color_entryema    = color.green
var color_fastema     = color.orange
var color_mediumema   = color.red
var color_slowema     = color.white
var color_veryslowema = color.purple

var line_entryema    = line.new(x1=na, y1=na, x2=na, y2=na, xloc=xloc.bar_time, extend=extend.right, color=show_hlines ? color_entryema    : na, style=line.style_dashed)
var line_fastema     = line.new(x1=na, y1=na, x2=na, y2=na, xloc=xloc.bar_time, extend=extend.right, color=show_hlines ? color_fastema     : na, style=line.style_dashed)
var line_mediumema   = line.new(x1=na, y1=na, x2=na, y2=na, xloc=xloc.bar_time, extend=extend.right, color=show_hlines ? color_mediumema   : na, style=line.style_dashed)
var line_slowema     = line.new(x1=na, y1=na, x2=na, y2=na, xloc=xloc.bar_time, extend=extend.right, color=show_hlines ? color_slowema     : na, style=line.style_dashed)
var line_veryslowema = line.new(x1=na, y1=na, x2=na, y2=na, xloc=xloc.bar_time, extend=extend.right, color=show_hlines ? color_veryslowema : na, style=line.style_dashed)

f_moveLine(_id, _x, _y) =>
    line.set_xy1(_id, _x,   _y)
    line.set_xy2(_id, _x+1, _y)

entryema    = ema(src, len1)
fastema     = ema(src, len2)
mediumema   = ema(src, len3)
slowema     = ema(src, len4)
veryslowema = ema(src, len5)

if (hour==0 and minute==0 and year(time)==year(timenow) and month(time)==month(timenow) and dayofmonth(time)==dayofmonth(timenow))
    f_moveLine(line_entryema,    time, entryema)
    f_moveLine(line_fastema,     time, fastema)
    f_moveLine(line_mediumema,   time, mediumema)
    f_moveLine(line_slowema,     time, slowema)
    f_moveLine(line_veryslowema, time, veryslowema)
    
plot(entryema,    color=show_emas ? color_entryema    : na, linewidth=1, title="Entry EMA")
plot(fastema,     color=show_emas ? color_fastema     : na, linewidth=1, title="Fast EMA")
plot(mediumema,   color=show_emas ? color_mediumema   : na, linewidth=1, title="Medium EMA")
plot(slowema,     color=show_emas ? color_slowema     : na, linewidth=1, title="Slow EMA")
plot(veryslowema, color=show_emas ? color_veryslowema : na, linewidth=1, title="Veryslow EMA")

---

哇！非常感谢你，伙计！！太棒了。我真的很感激。。。真的说不出话来，不客气。如果您认为它解决了您的问题，请将答案标记为已接受，以便其他人也能从中受益。谢谢。您好，米斯汀先生。再次感谢您对水平均线的帮助。我有另一个关于标记线的问题。我已经设法将“每周结算”显示为一个标签，其中包含以下代码行和更多代码行。但现在我试图用10、21等来标记水平均线，但徒劳无功。这有可能因为它们是变量而不起作用吗？你能为此提出一个新问题吗？将多个问题汇总成一个问题是违反SO的内部规则的。完成，谢谢你提供的信息。