如何在vbscript中将类的属性设置为不同的类？

我正在尝试在vbscript中执行类似的操作

Class cla
    Public a, b
End Class

Class clb
    Public c
End Class

Set mySubObj = new clb
mySubObj.c = "value_C"

Set myObj = new cla
myObj.a = "value_A"
myObj.b = mySubObj

msgBox(myObj.b.c)   

---

这不起作用，基本上我正在解析一个xml文档，然后处理一个用户定义的映射，该映射可以包含vbscript，在脚本中，变量可以像“myobj.b.c”一样访问。这只是一个简单的示例，但如果有任何帮助，我将不胜感激。

我知道了如何做到这一点，更多细节，你可以看看下面的代码，为我工作，希望这可能对其他人有用

Class ClassA 
    Private m_A 
    Private m_B 

    Public Property Get A
        A = m_A 
    End Property 

    Public Property Let A(value) 
        m_A = value 
    End Property 

    'Since this property is and object must use 
    'Set instead of Let, and must 
    'specifically Set the values 

    Public Property Get B 
        Set B = m_B 
    End Property

    Public Property Set B(value) 
        Set m_B = value
    End Property 
End Class 

Class ClassB
    Public C 
End Class 

Set a = New ClassA
a.a = "value1" 
Set a.b = new ClassB 
a.b.c = "value2" 

MsgBox(a.b.c) 'shows "value2

---

始终必须使用

set

将对象分配给某个对象。请不要在注释中发布代码。正如你所看到的，它变得一团糟。如果你自己找到了问题的答案：把它作为你自己的答案贴出来并接受它，这样它就可以算作一个已解决的问题。