Vbscript 脚本以显示PC中的所有IP地址，并让用户选择要使用的IP地址

你好

请检查我的代码

我甚至可以显示一个输入框，供用户选择他们想要使用的IP地址，这适用于运行Windows XP的多个NIC的PC。如何以字符串格式返回所选IP地址，而不是返回与所选内容对应的数字

如果我没有以正确的方式发布，我道歉

谢谢你的帮助

代码部分：

Dim longipvalue, a, returnvalueip
strComputer = "."
a=0
Set objWMIService = GetObject("winmgmts:" _
  & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
  ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled=TRUE")
longipvalue = "Please Select the correct IP address for this type of machine" & Chr(10) & Chr(10)
For Each IPConfig in IPConfigSet
  If Not IsNull(IPConfig.IPAddress) Then
    For i=LBound(IPConfig.IPAddress) to UBound(IPConfig.IPAddress)
      a=a+1
      longipvalue = longipvalue & a & ")   " & IPConfig.IPAddress(i) & VbCrLf  & VbCrLf
    Next
  End If
Next
returnvalueip = InputBox (longipvalue)
MsgBox returnvalueip

---

这可能适合您。
连接地址，然后拆分，并显示用户的选择

Dim longipvalue, a, returnvalueip
Dim ipAddr  'Concatenate all IP addresses with "|"

strComputer = "."
a=0
Set objWMIService = GetObject("winmgmts:" _
  & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set IPConfigSet = objWMIService.ExecQuery _
  ("Select * from Win32_NetworkAdapterConfiguration Where IPEnabled=TRUE")
longipvalue = "Please Select the correct IP address for this type of machine" & Chr(10) & Chr(10)

ipAddr = ""
For Each IPConfig in IPConfigSet
  If Not IsNull(IPConfig.IPAddress) Then
    For i=LBound(IPConfig.IPAddress) to UBound(IPConfig.IPAddress)
      a=a+1
      longipvalue = longipvalue & a & ")   " & IPConfig.IPAddress(i) & VbCrLf  & VbCrLf
      'Concatenate
      ipAddr = ipAddr & IPConfig.IPAddress(i) & "|"
    Next
  End If
Next

returnvalueip = InputBox (longipvalue)

' Show IP Address chosen
MsgBox Split(ipAddr, "|")(returnvalueip - 1)