Xml XSLT中select的除法和乘法值

只想在div之后将select的值乘以1000000，这是非常新的；我相信这对某人来说是个简单的问题。提前谢谢

<xsl:value-of select="AbsolutePos/@x div 80" />

想要乘以1000000，不要认为这是正确的，因此返回的值不正确

<xsl:value-of select="AbsolutePos/@x div 80 * 1000000" />

继续：具有以下XML

<AbsolutePos x="-1.73624e+006" y="-150800" z="40000"></AbsolutePos>

需要换成

<PInsertion>-21703,-1885,500</PInsertion>

-21703，-1885500

使用XSL

<PInsertion><xsl:value-of select="AbsolutePos/@x div 80 * 1000000" />,<xsl:value-of select="AbsolutePos/@y div 80" />,<xsl:value-of select="AbsolutePos/@z div 80" /></PInsertion>

，，

虽然收到

<PInsertion>NaN,-1885,500</PInsertion>

NaN，-1885500

---

假设取X值，然后除以80，再乘以10000返回-21703

如果XSLT处理器不识别科学符号，则必须自己进行计算-例如：

XSLT1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="AbsolutePos">
    <PInsertion>
        <xsl:apply-templates select="@*"/>
    </PInsertion>
</xsl:template> 

<xsl:template match="AbsolutePos/@*">
    <xsl:variable name="num">
        <xsl:choose>
            <xsl:when test="contains(., 'e+')">
                <xsl:variable name="factor">
                    <xsl:call-template name="power-of-10">
                        <xsl:with-param name="exponent" select="substring-after(., 'e+')"/>
                    </xsl:call-template>
                </xsl:variable>
                <xsl:value-of select="substring-before(., 'e+') * $factor" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="." />
            </xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <xsl:value-of select="$num div 80" />
    <xsl:if test="position()!=last()">
        <xsl:text>,</xsl:text>
    </xsl:if>
</xsl:template>

<xsl:template name="power-of-10">
    <xsl:param name="exponent"/>
    <xsl:param name="result" select="1"/>
    <xsl:choose>
        <xsl:when test="$exponent">
            <xsl:call-template name="power-of-10">
                <xsl:with-param name="exponent" select="$exponent - 1"/>
                <xsl:with-param name="result" select="$result * 10"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$result"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

,

请注意，这是一个不会处理负指数的简化示例

---

编辑

---

如果您的输入总是遵循（仅）@x以

########e+006的形式

的模式，那么您可以通过将

子字符串的值（绝对pos/@x，'e+'）

乘以12500（即10^6/80）来简化这一过程。

您的代码似乎没有问题。@x的值是什么？“因此返回的值不正确”一个特定的示例，包括输入和接收的结果将非常有用。对我的初始问题进行了上述修改，感谢heaps。并非所有XSLT处理器都会认识到

-1.73624e+006

是一个数字。这就是它失败和返回的地方；NaN，-1885500，我能做点什么吗？