Delphi 如何在TVirtualStringTree中绘制特殊级别的背景色

我尝试在VirtualStringTree的所有单独级别中使用背景色绘制高线文本。它看起来像是所有相同级别的选定节点。 下面的代码不起作用。请有人给个方向

procedure TMainForm.Tree1PaintText(Sender: TBaseVirtualTree; const TargetCanvas: TCanvas; Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType);
var  Data: PNodeData;LEVEL:INTEGER;  tree1node,tree4Node: PVirtualNode;
begin 
    Data := Tree1.GetNodeData(Node);
    Level := tree1.GetNodeLevel(node);

 case column of
     0:begin
        if Level = 0 then BEGIN
               TargetCanvas.Font.Style := TargetCanvas.Font.Style + [fsBold];
               TargetCanvas.Font.Color :=CLyellow;
               targetcanvas.Brush.Color :=clgreen;//don't work
               targetcanvas.Brush.Style :=bssolid;     

             END;
            if  Level = 1 then BEGIN
                  TargetCanvas.Font.Color :=CLaqua; 
                  targetcanvas.Brush.Color :=clgreen;
            end;
       end;

---

VT更快地填充单元格背景，在PrepareCell方法中更具体。所以现在尝试设置画布笔刷已经太迟了。尝试从OnBeforeCellPaint事件中填充节点矩形：

procedure TForm1.VirtualStringTree1BeforeCellPaint(Sender: TBaseVirtualTree;
  TargetCanvas: TCanvas; Node: PVirtualNode; Column: TColumnIndex;
  CellPaintMode: TVTCellPaintMode; CellRect: TRect; var ContentRect: TRect);
var
  R: TRect;
begin
  if CellPaintMode = cpmPaint then
  begin
    R := Sender.GetDisplayRect(Node, Column, True, False, True);
    R.Offset(0, -R.Top);
    case Sender.GetNodeLevel(Node) of
      0: TargetCanvas.Brush.Color := $0000F9FF;
      1: TargetCanvas.Brush.Color := $0000BFFF;
      2: TargetCanvas.Brush.Color := $000086FF;
    end;
    TargetCanvas.FillRect(R);
  end;
end;

预览：

---

一种方法是在

OnBeforeItemErase

事件中使用

eaColor

作为擦除操作：

procedure TMainForm.Tree1BeforeItemErase(Sender: TBaseVirtualTree; TargetCanvas: TCanvas;
          Node: PVirtualNode; ItemRect: TRect; var ItemColor: TColor; var EraseAction: TItemEraseAction);
begin
   if not Sender.Selected[Node] then begin
      case Sender.GetNodeLevel(Node) of
        0: ItemColor := clgreen;
        1: ItemColor := clAgua;
      end;
      EraseAction := eaColor;
   end;
end;

---

您好，我测试了代码。它可以在不同的列中显示背景颜色。“itemcolor”似乎仅适用于fillrect所有项目。如果fillrect仅用于项目文本（不包括空格），如何改进？。谢谢，项目擦除用于整行（即所有列），如果您需要更多控制，您可能必须使用自定义绘制。祝贺达到5k代表！：）