Delphi 如何以编程方式设置我的IP地址？

如何以编程方式设置IP地址

我的应用程序正在使用中的代码进行检查（尽管我不确定中的代码是否更好）

---

我希望能够为测试目的以编程方式设置地址。而且（我不知道这是否重要），即使我没有连接到任何网络（在笔记本电脑上或火车上），我也希望能够这样做。

要更改网络适配器的ip地址，可以使用WMI类的方法或WinApi方法

请尝试此使用WMI的示例

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils,
  ActiveX,
  Variants,
  ComObj;

procedure  SetStaticIpAddress(const NetworkCard, IPAddress, Mask :string);
const
  WbemUser    ='';
  WbemPassword='';
  WbemComputer='localhost';
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator   : OLEVariant;
  FWMIService     : OLEVariant;
  FWbemObjectSet  : OLEVariant;
  FWbemObject     : OLEVariant;
  FOutParams      : OLEVariant;
  vIpAddress      : OLEVariant;
  vMask           : OLEVariant;
  oEnum           : IEnumvariant;
  iValue          : LongWord;
begin
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);

  FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM Win32_NetworkAdapterConfiguration Where Description="%s"',[NetworkCard]),'WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  if oEnum.Next(1, FWbemObject, iValue) = 0 then
  begin
    vIpAddress   := VarArrayCreate([0, 0], varVariant);
    vIpAddress[0]:= IPAddress;
    vMask   := VarArrayCreate([0, 0], varVariant);
    vMask[0]:=  Mask;
    FOutParams:=FWbemObject.EnableStatic(vIpAddress, vMask);
    // 0 - Successful completion, no reboot required
    // 1 - Successful completion, reboot required
    Writeln(Format('ReturnValue  %s',[FOutParams]));
  end
  else
  Writeln('Network card not found');
end;


begin
 try
    CoInitialize(nil);
    try
      SetStaticIpAddress('Network card name','192.168.1.1','255.255.255.0');
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

---

简短回答：除非您在已知环境中执行系统级工作，否则通常不能。绝大多数系统都是通过服务器接收地址的，随意篡改自己的IP地址会导致连接丢失。如果你知道你所处的环境，并且你能安全地做到这一点，你就必须给我们一些与她合作的东西——你知道，那些小细节，比如什么操作系统，什么版本的操作系统。你有根/管理员权限吗？基本的东西。你的意思是改变你的应用程序看到的东西？一个简单的条件编译应该可以做到这一点。只需将获取ip的代码更改为set-1。+1，类似于什么呢？是的，这是有效的第三个选项：）+1同时为两者@鲁迪，我正在试密码。不过，这是一个愚蠢的问题——我怎么知道网络卡的价值是多少？@Mawg，这是网络卡@RRUZ的设备名，代码对其进行了处理（当我将WroteLn改为MessageDlg时）。那是一百万美元。当然，你得到了答案。