Delphi 如何在VCL样式的应用程序中使TListView标题居中？

我有一个列表视图控件（

ListView

），我用如下代码填充它：

var
  Item: TListItem;
  Column: TListColumn;
begin    
  ListView.ViewStyle := vsReport;

  Column := ListView.Columns.Add;
  Column.Width := 200;
  Column.Alignment:= taCenter;
  Column.Caption:= 'Column 1';

  Column:= ListView.Columns.Add;
  Column.Width := 200;
  Column.Alignment := taCenter;
  Column.Caption := 'Column 2';

  Item := ListView.Items.Add;
  Item.Caption := 'Item 1';
  Item.SubItems.Add('Subitem 1');
end;

问题是，当我在应用程序中使用VCL样式时，文本在列表视图标题中没有居中：

---

如何使标题标题在VCL样式的应用程序中居中？

负责绘制列标题的样式挂钩从不检查列的文本对齐方式，总是以左对齐方式绘制文本，这显然是一个疏忽

首先为祖先创建一个

Vcl.ComCtrls.TListViewStyleHook

的后代和一个类帮助器，以便我们可以访问我们需要的私有变量

TListViewStyleHookHelper = class helper for TListViewStyleHook
    function getFHeaderHandle: HWnd;
  end;

TListViewStyleHookEx = class(Vcl.ComCtrls.TListViewStyleHook)
  strict protected
    procedure DrawHeaderSection(Canvas: TCanvas; R: TRect; Index: Integer;
      const Text: string; IsPressed, IsBackground: Boolean); override;
  end;

确定方法：

uses
  Winapi.Commctrl;


function TListViewStyleHookHelper.getFHeaderHandle: HWnd;
begin
  Result := Self.FHeaderHandle;
end;


procedure TListViewStyleHookEx.DrawHeaderSection(Canvas: TCanvas; R: TRect;
  Index: Integer; const Text: string; IsPressed, IsBackground: Boolean);
var
  Item: THDItem;
  ImageList: HIMAGELIST;
  DrawState: TThemedHeader;
  IconWidth, IconHeight: Integer;
  Details: TThemedElementDetails;
  LListView: TListView;
  DT_Align: Integer;
begin
  FillChar(Item, SizeOf(Item), 0);
  Item.mask := HDI_FORMAT;
  Header_GetItem(getFHeaderHandle, Index, Item);
  if IsBackground then
    DrawState := thHeaderItemNormal
  else if IsPressed then
    DrawState := thHeaderItemPressed
  else
    DrawState := thHeaderItemNormal;

  Details := StyleServices.GetElementDetails(DrawState);
  StyleServices.DrawElement(Canvas.Handle, Details, R);

  ImageList := SendMessage(getFHeaderHandle, HDM_GETIMAGELIST, 0, 0);
  Item.mask := HDI_FORMAT or HDI_IMAGE;
  InflateRect(R, -2, -2);
  IconWidth := 0;
  if (ImageList <> 0) and Header_GetItem(getFHeaderHandle, Index, Item) then
  begin
    if Item.fmt and HDF_IMAGE = HDF_IMAGE then
    begin
      ImageList_Draw(ImageList, Item.iImage, Canvas.Handle, R.Left, R.Top,
        ILD_TRANSPARENT);
      ImageList_GetIconSize(ImageList, IconWidth, IconHeight);
      Inc(R.Left, IconWidth + 5);
    end;
  end;
  if IconWidth = 0 then
    Inc(R.Left, 2);

  DT_Align := 0;

  if Control is TListView then
  begin
    LListView := TListView(Control);
      if (Index > -1) and (Index < LListView.Columns.Count) then
        case LListView.Columns[Index].Alignment of
          taLeftJustify:
            DT_Align := 0;
          taRightJustify:
            DT_Align := 2;
          taCenter:
            DT_Align := 1;
        end;
  end;

  DrawControlText(Canvas, Details, Text, R, DT_VCENTER or DT_Align or
    DT_SINGLELINE or DT_END_ELLIPSIS);

end;

---

我给这个firemonkey贴上了标签，对吗？不，是它的vcl david（文件列表是listview）。XE6thanks@TLama，很抱歉，我在德尔福并不完美，我是新手。idk how to ask Truely您可以修改样式并进行更改，但是所有列标题的样式也会更改。也许有一个VCL风格的黑客在飞行中改变这一点？在样式设计器中，转到“对象>标题>部分”，然后在右侧找到TextAlign。也就是说，如果您希望这是系统范围内的。如果没有，你需要自己画或者找个黑客。这就是vcl风格的生活。我无法理解这种吸引力。我仍然记得WinAmp。事实上，正如我在问题中的评论所述，VCL样式实际上对此有自己的属性。我还没有测试过它，所以它可能不起作用（与VCL样式中的许多其他东西一样）。@Jerrydoge，是的，但正如我所说的，原始代码从未使用过该属性。您在样式设计器中看到的道具只是一组继承的属性，并不意味着它们被以任何方式使用。这实际上比VCL样式更常见。我知道您要求不要考虑

TListView

列对齐方式，但我在VCL样式中讨论了这一点-两个不同的属性。显然他们两个都没有被承认。我希望VCL样式中的设置至少优先于实际控件。

Initialization
 TCustomStyleEngine.RegisterStyleHook(TListView, TListViewStyleHookEx);

Finalization
 TCustomStyleEngine.UnRegisterStyleHook(TListView, TListViewStyleHookEx);