gnuplot：有选择地将某些键置于顶部

我正在尝试使用

gnuplot

绘制一个图形。由于空间有限，该图形是这样绘制的：

我正在考虑将前三个标签（

ins replace

、

bb split

和

func reorder

移到图的顶部，在外面！）

所以应该是这样的：

set key outside

但是基本上如何选择前三个键并将它们移动到外部？有可能吗

我把我的脚本放在这里：

set term pdf size 10,8 font "Arial,44"
set output "plot/bzip-ropbase-mix.pdf"
set size ratio 0.6
#set multiplot layout 1,1
set datafile separator ","
set offset 0, 0, 0, 0
set xtics norangelimit
set ytics nomirror
set termoption dashed
set ylabel "Gagdet Elimination Rate (%)"
set xlabel "Iteration"
set key bottom right
set yrange [0:110]
set style data linespoints
set key vertical maxrows 5
plot 'plot/bzip-ropbase-data.csv' using 11:xtic((int($0)%4)==0?   sprintf("%d", $0*50):"") title columnheader(11) pt 4 lw 1, \
'' using 12 title columnheader(12) pt 5 lw 4 ps .8 lc rgb "#4169E1", \
'' using 13 title columnheader(13) pt 6 lw 4 ps .8 lc rgb "#DAA520", \
'' using 14 title columnheader(14) pt 7 lw 4 ps .8 lc rgb "#FF7F50", \
'' using 15 title columnheader(15) pt 8 lw 4 ps .8 lc 7

---

谁能给我一些帮助吗？谢谢大家!

您无法自动执行此操作，但有办法解决此问题。首先要想到的是使用multiplot，然后首先绘制所有的函数和文件，这些函数和文件的标题是你想要的，然后是你想要的。您需要为第一个实例禁用图形边框等，然后为第二个实例启用它。要确保在两个

打印

实例期间打印区域保持不变，您需要硬设置边距：

set multiplot
set xrange [0:2.*pi]

# Set the margins
set lmargin at screen 0.1; set rmargin at screen 0.98
set tmargin at screen 0.8; set bmargin at screen 0.1

# Disable drawing borders and tics
unset border; unset tics

# Set position of the legend
set key tmargin

# Draw the first batch of stuff
plot cos(x) lc 1

# Enable drawing borders and tics
set border; set tics

# Set position of the legend
set key inside

# Draw the second batch of stuff
plot sin(x) lc 2

---

当涉及TeX和

gnuplot

之间的交互时，涉及

gnuplot

的问题可能会出现在主题上。我认为这是纯粹的

gnuplot

。在gnuplot中不能这样做。我能想象的唯一方法是覆盖两个图，一个是某些曲线和关键点在里面，另一个是其他曲线和关键点在外面。如果我是你，我会把所有东西都放在外面。@alfC，谢谢你的回答。。很抱歉，为什么要偏离主题…？@alfC，我正在

堆栈溢出

上发帖…你是对的，我想我点击了tex.exchange上的问题，我还以为它还在里面。