Oracle搜索所有表所有列中的字符串

我需要在oracle数据库中搜索所有表和列中的字符串。我在网上找到了下面的查询，但是当我执行它时，我得到了以下错误

谢谢你的帮助

ORA-06550: line 6, column 31:
PL/SQL: ORA-00904: "COLUMN_NAME": invalid identifier
ORA-06550: line 6, column 12:
PL/SQL: SQL Statement ignored
ORA-06550: line 8, column 30:
PLS-00364: loop index variable 'T' use is invalid
ORA-06550: line 7, column 4:
PL/SQL: Statement ignored
ORA-06550: line 12, column 38:
PLS-00364: loop index variable 'T' use is invalid
ORA-06550: line 12, column 16:
PL/SQL: Statement ignored

BEGIN  
  FOR t IN (SELECT table_name, column_name FROM all_tables) LOOP   
   EXECUTE IMMEDIATE    
    'SELECT COUNT(*) FROM '||t.table_name||' WHERE '||t.column_name||' = :1'   
     INTO match_count  
       USING v_search_string; 
          IF match_count > 0 THEN 
               dbms_output.put_line( t.table_name ||' '||t.column_name||' '||match_count );
           END IF; 
  END LOOP;
END;
/

---

至少，您需要查询所有的\u选项卡\u列，而不是所有的\u表

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP   
    EXECUTE IMMEDIATE    
      'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
      ' WHERE '||t.column_name||' = :1'   
       INTO match_count  
      USING v_search_string; 
    IF match_count > 0 THEN 
      dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
    END IF; 
  END LOOP;
END;
/

但是，如果您正在查找字符串，那么几乎可以肯定的是，您希望只查找可以存储字符串的列。例如，在日期列中搜索字符串是没有意义的。除非您对BLOB列包含的内容有大量的先验知识，并且能够解析BLOB列的二进制格式，否则在BLOB列中搜索字符串是没有意义的。考虑到这一点，我怀疑你想要更像

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner,
                   table_name, 
                   column_name 
              FROM all_tab_columns
             WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2', 
                                 'CLOB', 'NCLOB') ) 
  LOOP   
    BEGIN
      EXECUTE IMMEDIATE    
        'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
        ' WHERE '||t.column_name||' = :1'   
         INTO match_count  
        USING v_search_string; 
      IF match_count > 0 THEN 
        dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
      END IF; 
    EXCEPTION
      WHEN others THEN
        dbms_output.put_line( 'Error encountered trying to read ' ||
                              t.column_name || ' from ' || 
                              t.owner || '.' || t.table_name );
    END;
  END LOOP;
END;
/

---

当然，这将是非常慢的-您需要为表中的每个字符串列对每个表进行一次完全扫描。对于中等大小的表和中等数量的字符串列，这可能需要花费相当长的时间。

这样，通过查询，它给出了以下错误ORA-00942：表或视图不存在ORA-06512：在第12行，我如何让它恢复或忽略此错误error@Jim-我在第二个解决方案中添加了一个异常处理程序。我还添加了schema owner限定符，以防您可以访问架构之外的表。我必须声明v_search_string和match_count，并在隐式游标的SELECT中添加owner字段以获得这项工作。这是真正的宝石+1。@Blanthor-很好。我添加了局部变量声明并修复了查询。谢谢也许这是个愚蠢的问题，但是这个搜索查询是否进行区分大小写的搜索？为什么不使用某种方式的grep搜索数据库文件呢？至少这样，您可以获得文件/块偏移，并找到有问题的表。