Sql 从关闭的文件中获取最后一行和最后一列或UsedRange（并保持其关闭-ADO）

我需要将UsedRange从七个关闭的文件复制到一个新工作簿。每个源文件大约有200米，因此我想在不打开它们的情况下提取信息

我从这个网站上读到了一些很好的信息，但是这里的函数需要提取特定的范围作为参数。不幸的是，这个范围发生了变化，所以我想找到一种方法来知道如何获取最后一列和最后一行

提前感谢,

迈克

从关闭的文件中获取最后一行和最后一列或UsedRange（并保持其关闭-ADO）。。。 我想找到一种方法来知道如何获取最后一列和最后一行

这就是你想要的吗

Option Explicit

Private Const adOpenKeyset As Integer = 1
Private Const adCmdText As Integer = 1

Sub Sample()
    Dim MyExcelFile As String
    Dim MyConnectionString As String
    Dim SQLString As String
    Dim MyCon As Object, MyRecordset As Object
    Dim lRow As Long, lCol As Long
    
    '~~> Change this to the relevant excel file
    MyExcelFile = "C:\Users\routs\Desktop\Test.xlsx"
    
    '~~> Connection string
    MyConnectionString = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & _
                         MyExcelFile & _
                        ";Extended Properties=""Excel 12.0 Xml;HDR=YES"";"
                        
    Set MyCon = CreateObject("ADODB.Connection")
    MyCon.Open ConnectionString:=MyConnectionString
    
    '~~> Getting details from Sheet1. Change as applicable
    SQLString = "SELECT * FROM [Sheet1$]"
    
    Set MyRecordset = CreateObject("ADODB.RecordSet")
    MyRecordset.Open Source:=SQLString, _
                     ActiveConnection:=MyCon, _
                     CursorType:=adOpenKeyset, _
                     Options:=adCmdText
                     
    MyRecordset.MoveLast
    
    '~~> Last Row
    lRow = MyRecordset.RecordCount + 1
    '~~> Last Column
    lCol = MyRecordset.Fields.Count
    
    MsgBox "Last Row:=" & lRow & vbNewLine & _
           "Last Column:=" & lCol
    
    MyRecordset.Close
    MyCon.Close
End Sub

---

那正是我想要的！！谢谢有关于如何使用ADODB.RecordSet对象的参考书目吗？我的网站上有一套很好的代码，但它被黑客攻击了。我正在重建它。同时，您可以随时用谷歌搜索VBA CreateObject（“ADODB.RecordSet”）