Delphi 在TGraphic控件中将jpg设置为位图

正在尝试将背景图像添加到控件

TCard（远程控制）

 procedure TCard.SetBitmap(image: TBitmap);
 begin
   bitmap1 := Tbitmap.create();
   bitmap1.Assign(image);
   canvas.draw(0,0,bitmap1);
 end;

在Form1按钮上单击，我想将图像添加到tcard组件

    procedure TForm1.Button1Click(Sender: TObject);
var
  image : Tbitmap;
  jpg: TJpegImage;
begin
  image := TBitmap.create();
  jpg := Tjpegimage.Create();
  jpg.LoadFromFile(dir+'\pics\backcard.jpg');
  image.Assign(jpg);
  card1.setbitmap(image);
  card1.Repaint;
  image.Destroy;
  jpg.Destroy;
 end;

---

当我运行这个时，什么都没有发生。如何将此图像设置为TCard组件的背景？

下面是一个为

tgraphicsontrol

子体设置背景图像的示例，以及一个使用它的示例（它在表单的

OnCreate

中使用

TBitmap

，在

按钮1中使用
TJpegImage
来演示两者）。它只需要一个新的空白VCL表单应用程序，该应用程序上有一个
t按钮
，即可启动

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Jpeg, StdCtrls;

type
  TCard = class(TGraphicControl)
  private
    FBackGround: TBitmap;
    procedure SetBackground(Value: TBitmap); overload;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    procedure Paint; override;
  published
    property BackGround: TBitmap read FBackGround write SetBackground;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    FCard: TCard;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TCard }

constructor TCard.Create(AOwner: TComponent);
begin
  inherited;
  FBackGround := TBitmap.Create;
end;

destructor TCard.Destroy;
begin
  FBackground.Free;
  inherited;
end;

procedure TCard.Paint;
begin
  inherited;
  Self.Canvas.StretchDraw(Self.ClientRect, FBackGround);
end;

procedure TCard.SetBackground(Value: TBitmap);
begin
  FBackGround.Assign(Value);
  //Self.SetBounds(Left, Top, FBackGround.Width, FBackGround.Height);
  Invalidate;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Image: TJPEGImage;
  Bmp: TBitmap;
begin
  Image := TJPEGImage.Create;
  Bmp := TBitmap.Create;
  try
    Image.LoadFromFile(PathToSomeJPEGFile);
    Bmp.Assign(Image);
    FCard.BackGround := Bmp;
  finally
    Bmp.Free;
    Image.Free;
  end;
end;

procedure TForm4.FormCreate(Sender: TObject);
var
  Bmp: TBitmap;
begin
  FCard := TCard.Create(Self);
  FCard.Parent := Self;
  Bmp := TBitmap.Create;
  try
  // Load a standard image from the backgrounds folder (D2007).
    Bmp.LoadFromFile('C:\Program Files (x86)\Common Files\CodeGear Shared\Images\BackGrnd\GREENBAR.BMP');
    FCard.BackGround := Bmp;
  finally
    Bmp.Free;
  end;
end;


end.

您的
SetBitmap
代码只创建一个位图并为其分配一些内容。什么是
位图1
，它在哪里声明，它做什么？你还没有包括这些信息。另外，假设
bitmap1
是
TCard
的一个属性，那么它包含的任何以前的内容会发生什么情况？bitmap1被声明为TCard的私有内容。我不知道如何将其设置为Tcard的背景。现在它只做你说的。只是将其分配给位图1。我尝试过使用canvas.draw，但认为这不是正确的方向。所以，在它分配bitmap1后，我尝试了一些东西，比如
canvas.draw（0,0，bitmap1）
一旦指定位图，就必须使用控件的
Canvas
方法（如
draw
或
StretchDraw
）实际绘制位图（或者简单地让
TCard
包含
TImage
并将位图指定给该位图，然后让
TImage
处理绘制过程）。它不仅仅因为声明了位图而神奇地出现在屏幕上。：-）（仅供记录：我不是那个否决你的问题的人。我只是在评论中要求澄清。）@Glen，如果你想为组件提供更灵活的图形对象，请尝试使用
t图片
，就像
TImage
一样。您可以向背景图像添加更好的格式灵活性，因为这样就足以将例如
JPEG
单元添加到
uses
子句中，并调用
LoadFromFile
传递JPEG文件的路径。或者，通过向uses子句添加
PngImage
，可以为其添加PNG格式支持。举个例子，看一看。它还包括如何加载图像的示例。这正是我想要的。因为我除了一个表单、一个按钮和一个tcard组件之外没有别的东西。我看到了一些我错过的东西。试着现在就开始工作。
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Jpeg, StdCtrls;

type
  TCard = class(TGraphicControl)
  private
    FBackGround: TBitmap;
    procedure SetBackground(Value: TBitmap); overload;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    procedure Paint; override;
  published
    property BackGround: TBitmap read FBackGround write SetBackground;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    FCard: TCard;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TCard }

constructor TCard.Create(AOwner: TComponent);
begin
  inherited;
  FBackGround := TBitmap.Create;
end;

destructor TCard.Destroy;
begin
  FBackground.Free;
  inherited;
end;

procedure TCard.Paint;
begin
  inherited;
  Self.Canvas.StretchDraw(Self.ClientRect, FBackGround);
end;

procedure TCard.SetBackground(Value: TBitmap);
begin
  FBackGround.Assign(Value);
  //Self.SetBounds(Left, Top, FBackGround.Width, FBackGround.Height);
  Invalidate;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Image: TJPEGImage;
  Bmp: TBitmap;
begin
  Image := TJPEGImage.Create;
  Bmp := TBitmap.Create;
  try
    Image.LoadFromFile(PathToSomeJPEGFile);
    Bmp.Assign(Image);
    FCard.BackGround := Bmp;
  finally
    Bmp.Free;
    Image.Free;
  end;
end;

procedure TForm4.FormCreate(Sender: TObject);
var
  Bmp: TBitmap;
begin
  FCard := TCard.Create(Self);
  FCard.Parent := Self;
  Bmp := TBitmap.Create;
  try
  // Load a standard image from the backgrounds folder (D2007).
    Bmp.LoadFromFile('C:\Program Files (x86)\Common Files\CodeGear Shared\Images\BackGrnd\GREENBAR.BMP');
    FCard.BackGround := Bmp;
  finally
    Bmp.Free;
  end;
end;


end.