Fortran 写入/dev/null时记录结束

在我们的数字软件中，我在升级集群后遇到了一个奇怪的错误。 即：

At line 501 of file /home/weser/code/neci/src/fcimc_helper.F90 (unit = 6, file = '/dev/null')
Fortran runtime error: End of record

在这一行中有一个打印到stdout的

print*，

语句

在我们的程序中，关闭并重新打开所有非根MPI进程的标准输出，以写入

/dev/null

。 （除调试模式外，每个非根MPI进程的标准输出将重定向到单独的文件。）

我试图为这个问题创建一个最小的示例，如下所示：

  program stdout_to_dev_null
      use iso_fortran_env, only: stdout => output_unit
      use mpi_f08  ! also works with plain mpi
      implicit none(type, external)
  
      integer :: rank, n_procs, ierror
      integer, parameter :: root = 0 
  
      call MPI_INIT(ierror)
      call MPI_COMM_SIZE(MPI_COMM_WORLD, n_procs, ierror)
      call MPI_COMM_RANK(MPI_COMM_WORLD, rank, ierror)
  
      if (rank /= root) then
          close(stdout, status="keep")
          open(stdout, file="/dev/null", recl=8192)
      end if
  
      write(stdout, *) 'Size is ', n_procs
      write(stdout, *) 'node', rank, ': Hello world'
  
      block
          integer :: i
          character(:), allocatable :: large_string
          allocate(character(len=5000) :: large_string)
  
          do i = 1, len(large_string)
              large_string(i : i) = 'A' 
          end do
  
          write(stdout, *) large_string
      end block
  
  
      call MPI_FINALIZE(ierror)
  
  end program

问题是，当使用

mpirun

手动运行时，这个最小的示例完全按照预期工作，但当实际发送到集群时，就像其他繁重的计算一样

---

现在我有三个问题：在这样的代码中，当关闭和重新打开STDOUT时，我是否有未定义的行为，而在最简单的示例中，我只是很幸运？如何在

/dev/null

中有记录结尾？如何正确解决此问题？

此问题与MPI无关，也与集群中的差异无关。ª 这是一个有问题的代码，它在

gfortran

中失败，但在

ifort

下工作纯属运气

如果以固定记录长度（

recl=…

）打开文件，则write语句不得超过此长度，即使输出转到

/dev/null

。 修复方法就是不使用固定的记录长度打开，并省略

recl=…

参数

显然，

ifort

的运行时库更为宽松，甚至在写入对象的字节长度大于

open

语句中指定的记录长度时也能工作

在下面的示例中，最后一个

write

语句在

gfortran

下失败

program stdout_to_dev_null
    use iso_fortran_env, only: stdout => output_unit
    implicit none(type, external)

    integer, parameter :: rec_length = 10

    write(stdout, *) 'asdf'

    close(stdout, status="keep")

    open(stdout, file="/dev/null")
    block
        integer :: i
        character(:), allocatable :: large_string

        allocate(character(len=rec_length - 1) :: large_string)

        do i = 1, len(large_string)
            large_string(i : i) = 'A'
        end do

        write(stdout, *) large_string

        deallocate(large_string)
        allocate(character(len=rec_length + 1) :: large_string)

        do i = 1, len(large_string)
            large_string(i : i) = 'A'
        end do

        write(stdout, *) large_string
    end block
    close(stdout, status="keep")

    open(stdout, file="/dev/null", recl=rec_length)
    block
        integer :: i
        character(:), allocatable :: large_string

        allocate(character(len=rec_length - 1) :: large_string)

        do i = 1, len(large_string)
            large_string(i : i) = 'A'
        end do

        write(stdout, *) large_string

        deallocate(large_string)
        allocate(character(len=rec_length + 1) :: large_string)

        do i = 1, len(large_string)
            large_string(i : i) = 'A'
        end do

        ! The following statement fails
        write(stdout, *) large_string
    end block
    close(stdout, status="keep")

end program

---

对于这个问题，新旧集群之间的相关区别在于，我们在新集群上使用

gfortran+OpenMPI

，在旧集群上使用

ifort+IntelMPI