Parallel processing 几个带等待的aRFC，如何在回调中同步访问变量？

我使用异步RFC调用在SAP中执行一些并行工作。在这里您可以看到我的伪代码

* class variable
data: gv_counter type i .

....

method start_tasks .

    do 10 times .

        call function 'my_remote_function'
            starting new task task_identifier
            calling task_finish on end of task .

    enddo .

    wait for asynchronous tasks until gv_counter eq 10 .    

endmethod .

.....

method task_finish .

    gv_counter = gv_counter + 1 .

endmethod .

正如你所看到的，我启动了10个进程，我一直等到它们全部完成

我的问题是关于方法

task\u finish

和对全局类变量

gv\u counter

的访问。如何确保对变量

gv_计数器的访问是同步的

例如，在Java中，我会这样做：

synchronized {
    gv_counter += 1 ;
}

以下是SAP对该主题的引用

增补2

。。。{调用meth}|{在任务结束时执行subr}


如果在一个程序段中注册了多个回调例程，则当工作进程在滚入中更改时，它们将以未定义的顺序执行

对我来说，这意味着他们将一个接一个地（按顺序）执行，但这是没有定义的。这意味着您的变量将始终达到10的值

实际上，您可以调试它，以查看在
task\u finish
方法中放置断点时它是如何按顺序处理的。这是我的例子

REPORT ZZZ.

CLASS lcl_main DEFINITION FINAL CREATE PRIVATE.
  PUBLIC SECTION.
    CLASS-METHODS:
      main,
      task_finish
        IMPORTING
          p_task TYPE clike.
  PRIVATE SECTION.
    CLASS-DATA:
      gv_counter TYPE i.
    CLASS-METHODS:
      start_tasks.
ENDCLASS.

CLASS lcl_main IMPLEMENTATION.
  METHOD main.
    start_tasks( ).
  ENDMETHOD.

  METHOD start_tasks.
    DATA: l_task TYPE string.
    DO 10 TIMES.
      l_task = sy-index.
      CALL FUNCTION 'Z_ARFC_ECHO'
        STARTING NEW TASK l_task
        CALLING task_finish ON END OF TASK
        EXPORTING
          i_value       = sy-index.

    ENDDO.

    WAIT FOR ASYNCHRONOUS TASKS UNTIL gv_counter = 10.
  ENDMETHOD.

  METHOD task_finish.
    DATA: l_value TYPE sy-index.
    RECEIVE RESULTS FROM FUNCTION 'Z_ARFC_ECHO'
      IMPORTING
        e_echo = l_value.

    WRITE: /, p_task, l_value.

    gv_counter = gv_counter + 1.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  lcl_main=>main( ).

我的RFC如下所示

FUNCTION Z_ARFC_ECHO.
*"----------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(I_VALUE) TYPE  SY-INDEX
*"  EXPORTING
*"     VALUE(E_ECHO) TYPE  SY-INDEX
*"----------------------------------------------------------------------

e_echo = i_value.

ENDFUNCTION.

同样有趣的是（文档中也提到了）类似于
WRITE
的列表输出语句没有在这样的处理程序中处理，因此，在执行上述报告的最后，您看不到任何打印内容。
没有“synchronized”这样的事情在ABAP中，因为ABAP中没有线程。您的代码中是否存在争用情况？为了澄清“它们将被执行”，您指的是“回调例程”，而不是“RFC任务”。确实如此，在异步RFC调用的所有进程完成后。抱歉，再次挑剔，但不是“在所有进程完成后”，每项任务一完成，它就在运行，但从来没有两个任务是并行的，总是按顺序进行的。