Stata 使用条形图/条形图绘制分类变量

我正在尝试绘制九月和十月波浪的条形图。如图所示，您可以看到id是跨时间被调查的个人。所以在一张图上，我需要画出9月的内部，10月的内部，9月的外部，10月的外部，并且只需要显示在9月的内部，10月的内部，9月的外部，10月的外部中说是的人的比例。并非所有类别都必须考虑在内

此外，我还必须为每个类别显示95%置信区间的胡须

* Example generated by -dataex-. For more info, type help dataex
clear
input float(id sept_outhouse sept_inhouse oct_outhouse oct_inhouse)
 1 1 1 1 1
 2 2 2 2 2
 3 3 3 3 3
 4 4 3 3 3
 5 4 4 3 3
 6 4 4 3 3
 7 4 4 4 1
 8 1 1 1 1
 9 1 1 1 1
10 1 1 1 1
end
label values sept_outhouse codes
label values sept_inhouse codes
label values oct_outhouse codes
label values oct_inhouse codes
label def codes 1 "yes", modify
label def codes 2 "no", modify
label def codes 3 "don't know", modify
label def codes 4 "refused", modify

save tokenexample, replace 

rename (*house) (house*)
reshape long house, i(id) j(which) string 
replace which = subinstr(proper(which), "_", " ", .)
gen yes = house == 1
label def WHICH 1 "Sept Out" 2 "Sept In" 3 "Oct Out" 4 "Oct In"
encode which, gen(WHICH) label(WHICH)
statsby, by(WHICH) clear: ci proportion yes, jeffreys 

set scheme s1color 
twoway scatter mean WHICH ///
|| rspike ub lb WHICH, xla(1/4, noticks valuelabel) xsc(r(0.9 4.1)) ///
xtitle("") legend(off) subtitle(Proportion Yes with 95% confidence interval)

这必须向后解决

均值和置信区间必须使用

双向

绘制，因为

图形条

在这里是一条死胡同，因为它也不允许有胡须

在绘制图形之前，必须将置信限放入变量中。一些图形命令，特别是

图形栏

，将为您计算平均值，但正如所说，这是一条死胡同。所以，我们也需要计算平均值

要做到这一点，您需要一个“是”的指示符变量

我所知道的获得结果的最佳方法是

将

重塑为不同的结构，然后在

statsby

下应用

ci比例

作为详细说明，选项

jeffreys

明确表示置信区间计算有不同的方法。你应该在知情的情况下选择一个

---

到目前为止，您尝试了什么<代码>帮助图形栏是一个很好的起点。这是一个完整的小项目，数据显示清晰但笨拙，代码尝试次数为零。我同意前一位选民的看法，那就是这是一个糟糕的问题。请以代码形式展示数据示例，并展示一些代码尝试。因此，这不是一个代码编写服务。Stata tag wiki为发布一个好问题提供了冗长的建议。