Unity3d 在单个网格上渲染多个材质

在Unity3D中，我尝试渲染一个生物，并在它被选中时显示一个轮廓

只有该生物被渲染为罚款：

我下载了一个，并将其作为第二种材质应用于我的网格：

展开的材质如下所示：

然而，结果与预期完全不同：

在对材质和着色器了解不多的情况下，我尝试四处摆弄，发现如果将标准材质的渲染模式更改为透明，结果看起来很好：

但现在，只有生物以一种奇怪的方式呈现，四肢与身体重叠：

---

实现我所要做的事情的正确方法是什么？您有我可以阅读更多内容的资源吗？

您的设置存在的问题是渲染队列。透明对象在不透明对象之后渲染，所以您的轮廓仅绘制在生物的顶部。如果要更改渲染顺序，必须将具有轮廓的对象视为“特殊”不透明对象（例如绘制普通对象、绘制轮廓、绘制生物）

以下是两个备选方案：

使用

Cull Front

-此着色器基本上是在原始对象的顶部绘制对象的更大副本，如外壳。“Cull Front”使其能够绘制对象后面的壳的背面，而不是正面

使用模具缓冲区标记绘制原始对象的区域，并在绘制轮廓时跳过该区域 下面是着色器的修改版本（已删除第二个颜色过程和曲面着色器过程，因为您不使用它们）。这是模具缓冲区选项。如果您想尝试另一种方法，请删除第一道工序，即第二道工序中的模具块，并将

Cull Back

替换为

Cull Front

Shader "Outlined/UltimateOutline"
{
    Properties
    {
        _Color("Main Color", Color) = (0.5,0.5,0.5,1)       

        _FirstOutlineColor("Outline color", Color) = (1,0,0,0.5)
        _FirstOutlineWidth("Outlines width", Range(0.0, 2.0)) = 0.15        

        _Angle("Switch shader on angle", Range(0.0, 180.0)) = 89
    }
    CGINCLUDE
    #include "UnityCG.cginc"

    struct appdata {
        float4 vertex : POSITION;
        float4 normal : NORMAL;
    };

    uniform float4 _FirstOutlineColor;
    uniform float _FirstOutlineWidth;

    uniform float4 _Color;
    uniform float _Angle;

    ENDCG

    SubShader{              
        Pass {
            Tags{ "Queue" = "Transparent-1" "IgnoreProjector" = "True" }
            ZWrite Off
            Stencil {
                Ref 1
                Comp always
                Pass replace
            }
            ColorMask 0
        }

        //First outline
        Pass{
            Tags{ "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }
            Stencil {
                Ref 1
                Comp NotEqual
            }

            Blend SrcAlpha OneMinusSrcAlpha
            ZWrite Off
            Cull Back      //Replace this with Cull Front for option 1
            CGPROGRAM

            struct v2f {
                float4 pos : SV_POSITION;
            };

            #pragma vertex vert
            #pragma fragment frag

            v2f vert(appdata v) {
                appdata original = v;

                float3 scaleDir = normalize(v.vertex.xyz - float4(0,0,0,1));
                //This shader consists of 2 ways of generating outline that are dynamically switched based on demiliter angle
                //If vertex normal is pointed away from object origin then custom outline generation is used (based on scaling along the origin-vertex vector)
                //Otherwise the old-school normal vector scaling is used
                //This way prevents weird artifacts from being created when using either of the methods
                if (degrees(acos(dot(scaleDir.xyz, v.normal.xyz))) > _Angle) {
                    v.vertex.xyz += normalize(v.normal.xyz) * _FirstOutlineWidth;
                }
                else {
                   v.vertex.xyz += scaleDir * _FirstOutlineWidth;
                }

                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                return o;
            }

            half4 frag(v2f i) : COLOR{
                return _FirstOutlineColor;
            }
        ENDCG
        }
    }
    Fallback "Diffuse"
}

---

看起来您的其他材质也被设置为“透明”。您所说的“其他材质”是什么意思？我将生物的材质（蓝色PBR）设置为透明。（在图3中，您可以看到我更改的渲染模式被标记。如果该生物设置为透明，您将获得上一张图像中显示的效果。“透明”的整体概念是Z缓冲区不受影响，因此后续绘制将覆盖或与开始时的任何材质混合。您需要多个材质（大纲和BluPBR），或在着色器中弄脏手。您是否尝试过使用大纲材质将主颜色设置为完全透明，并保持主材质不变？我不了解着色器，但您的PBR需要基于顶点的深度测试才能正常工作。但是，一般来说，您不必使任何材质透明必须让它与其他东西一起工作。它对渲染性能影响很大！@3Dave我有两种不同的材质，但当我应用这两种材质时，只有一种显示出来。