Coq 关于不同类型等式的假设和证明定理（证明两个偶数之和的相依类型的交换性）

简短的问题是：如何从下面的代码证明（或如何以“更好”的方式假设）定理

Inductive even : nat -> Type :=
| EZ : even 0
| ES : forall n, odd n -> even (S n)
with odd : nat -> Type :=
| OS : forall n, even n -> odd (S n).

Fixpoint even_sum n1 n2 (e1 : even n1) : even n2 -> even (n1 + n2) :=
  match e1 with
  | EZ => fun e2 => e2
  | ES _ o1 => fun e2 => ES (odd_sum o1 e2)
  end
with odd_sum n1 n2 (o : odd n1) : even n2 -> odd (n1 + n2) :=
  match o with
  | OS _ e => fun e2 => OS (even_sum e e2)
  end.

Theorem add_comm_right_0 : forall n, n = n + 0.
    induction n; crush.
Defined.

Theorem add_comm : forall (n m : nat), n + m = m + n.
  induction n; intros.
  apply add_comm_right_0.
  crush.
Defined.  

Theorem even_sum_commut' : forall n1 n2, even (n1 + n2) -> even (n2 + n1).
  intros.  
  rewrite add_comm.
  apply H.
Defined.
 
Theorem odd_sum_commut' : forall n1 n2, odd (n1 + n2) -> odd (n2 + n1).
  intros. rewrite add_comm. assumption.
Defined.

Scheme even_mut := Induction for even Sort Prop
  with odd_mut := Induction for odd Sort Prop.

Theorem even_sum_right_0 : forall n1 (e1 : even n1),
    e1 = even_sum_commut' n1 0 (even_sum e1 EZ).
Proof.
   apply (even_mut (fun n en => en = even_sum_commut' n 0 (even_sum en EZ)) 
                   (fun n on => on = odd_sum_commut' n 0 (odd_sum on EZ))). 
   - simpl. reflexivity. 
   - intros. simpl.
Admitted.

Theorem even_sum_commut : forall n1 n2 (e1 : even n1) (e2 : even n2),
    even_sum e1 e2 = even_sum_commut' _ _ (even_sum e2 e1).
Proof.
Admitted.

如我所见，

偶数和e2

和

偶数和e2

是相同的术语（根据偶数和的定义）。所以，在我看来，这个定理应该是可以证明的。但我不确定（类型不同，在我看来这是问题的一部分）

长话短说如下

我正在读亚当·克利帕拉的书（非常感谢作者！）。而且我还试着解决练习题。前4个练习对我来说是解决它们的乐趣（因为这是一件相当快的事情）。但我面临着一个练习，如果修改它，它会变得更有趣

归纳类型的第0.1章，练习5

定义偶数和奇数自然数的相互归纳类型，使任何自然数同构于这两种类型之一的值。（这个问题并不要求你证明对应关系，尽管对任务的一些解释可能是有趣的练习。）写一个函数，计算两个偶数之和， 这样，函数类型可以保证输出也是均匀的。证明这一点 函数是可交换的

使用下一个定义可以轻松解决此任务：

Inductive nat_even : Type :=
  | EZ' : nat_even
  | EN' : nat_odd -> nat_even
with nat_odd : Type :=
  | ON' : nat_even -> nat_odd.

但我想尝试一下上面给出的另一个定义（受书中给出的定义启发）

一个小的解释。请注意：这不是教科书上的练习，这是（我自己的）修改，使任务有点不容易解决（至少对我来说）。这本书最初的任务是相当艰难的（好吧，你需要考虑一下，但仍然如此）。所以，这里没有任何可能的“违反荣誉准则”的行为

任何想法都是受欢迎的，我很想知道“如何以更好的方式去做”或者“如何以另一种方式去做”。我的意思是“如何表述和证明不同类型的定理，这是可能的”

---

也许有人能给我一个教科书/论文的链接让我阅读。这也很好。

解决此类问题的最佳方法是忘记类型依赖关系。在这种情况下，

偶数n

和

奇数n

的证明完全以

n

为特征，如下引理所示

From Coq Require Import ssreflect ssrfun.
Require Import Coq.Arith.Arith.

Set Implicit Arguments.

Inductive even : nat -> Type :=
| EZ : even 0
| ES : forall n, odd n -> even (S n)
with odd : nat -> Type :=
| OS : forall n, even n -> odd (S n).

Fixpoint even_or_odd (n : nat) : even n + odd n :=
  match n with
  | 0   => inl EZ
  | S m => match even_or_odd m with
           | inl p => inr (OS p)
           | inr p => inl (ES p)
           end
  end.

Fixpoint nat_of_evenK n (p : even n) : even_or_odd n = inl p :=
  match p with
  | EZ      => erefl
  | @ES m p => congr1 (fun r : even m + odd m =>
                         match r with
                         | inl q => inr (OS q)
                         | inr q => inl (ES q)
                         end)
                      (nat_of_oddK p)
  end

with nat_of_oddK n (p : odd n) : even_or_odd n = inr p :=
  match p with
  | @OS m p => congr1 (fun r : even m + odd m =>
                         match r with
                         | inl q => inr (OS q)
                         | inr q => inl (ES q)
                         end)
                      (nat_of_evenK p)
  end.

Lemma even_irrel n (p q : even n) : p = q.
Proof.
suff [//] : inl p = inl q :> even n + odd n.
by rewrite -2!nat_of_evenK.
Qed.

Lemma odd_irrel n (p q : odd n) : p = q.
Proof.
suff [//] : inr p = inr q :> even n + odd n.
by rewrite -2!nat_of_oddK.
Qed.

特别是,

Definition even_comm_cast n m : even (n + m) -> even (m + n) :=
  let: erefl := Nat.add_comm n m in id.

Lemma even_addC n m (p : even (n + m)) (q : even (m + n)) :
  p = even_comm_cast m n q.
Proof.
rewrite /even_comm_cast.
case: (n + m) / Nat.add_comm p => //= p; exact: even_irrel.
Qed.

---

我想你这样做是为了自学，但我们还是尽量避免给课本上的练习提供帮助（因为学生以后很容易找到）/亚瑟，谢谢你的通知。我对问题补充了解释。简历：如果你帮助我，你不会给出任何教科书上练习的答案，因为没有教科书上有这样的练习（至少我知道）。所以，没什么好担心的。对不起，我一开始不明白！亚瑟，谢谢你的解释。太棒了！