C# 用于Unity中谷歌硬纸板的虚拟现实GUI

我正在unity中创建一个简单的谷歌纸板游戏，我想增加分数。我知道如何正常地做，但在虚拟现实中它不适合我。我试着把文字和显示分数放进去，看起来不错（不完全是因为它只显示一只眼睛），但在我的手机上测试后，文字在完全不同的地方。你知道正确的方法是什么吗？

创建一个世界空间画布，并将该画布连接到相机。这就是我在虚拟现实游戏中获得用户界面的方式

您需要为您的世界空间UI对象提供一个自定义着色器，该着色器具有覆盖的渲染顺序，并且已关闭ZTest

这是带有必要更改的默认UI着色器的副本。我们应该做到这一点。只需使用此着色器制作材质，并将其应用于在WorldSpace UI中的几何体顶部绘制的所有内容

 Shader "UI/Default_OverlayNoZTest"
 {
     Properties
     {
         [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
         _Color ("Tint", Color) = (1,1,1,1)

         _StencilComp ("Stencil Comparison", Float) = 8
         _Stencil ("Stencil ID", Float) = 0
         _StencilOp ("Stencil Operation", Float) = 0
         _StencilWriteMask ("Stencil Write Mask", Float) = 255
         _StencilReadMask ("Stencil Read Mask", Float) = 255

         _ColorMask ("Color Mask", Float) = 15
     }

     SubShader
     {
         Tags
         { 
             "Queue"="Overlay" 
             "IgnoreProjector"="True" 
             "RenderType"="Transparent" 
             "PreviewType"="Plane"
             "CanUseSpriteAtlas"="True"
         }

         Stencil
         {
             Ref [_Stencil]
             Comp [_StencilComp]
             Pass [_StencilOp] 
             ReadMask [_StencilReadMask]
             WriteMask [_StencilWriteMask]
         }

         Cull Off
         Lighting Off
         ZWrite Off
         ZTest Off
         Blend SrcAlpha OneMinusSrcAlpha
         ColorMask [_ColorMask]

         Pass
         {
         CGPROGRAM
             #pragma vertex vert
             #pragma fragment frag
             #include "UnityCG.cginc"

             struct appdata_t
             {
                 float4 vertex   : POSITION;
                 float4 color    : COLOR;
                 float2 texcoord : TEXCOORD0;
             };

             struct v2f
             {
                 float4 vertex   : SV_POSITION;
                 fixed4 color    : COLOR;
                 half2 texcoord  : TEXCOORD0;
             };

             fixed4 _Color;

             v2f vert(appdata_t IN)
             {
                 v2f OUT;
                 OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
                 OUT.texcoord = IN.texcoord;
 #ifdef UNITY_HALF_TEXEL_OFFSET
                 OUT.vertex.xy += (_ScreenParams.zw-1.0)*float2(-1,1);
 #endif
                 OUT.color = IN.color * _Color;
                 return OUT;
             }

             sampler2D _MainTex;

             fixed4 frag(v2f IN) : SV_Target
             {
                 half4 color = tex2D(_MainTex, IN.texcoord) * IN.color;
                 clip (color.a - 0.01);
                 return color;
             }
         ENDCG
         }
     }
 }

---

我得说，功劳归于

；设置RenderTexture并使您的/用户界面成为唯一绘制在其上的对象，然后将RenderTexture粘贴到您世界中的其他对象上

您是这样做的吗？它工作得很好，但是如何使这个UI始终可见（它有时隐藏在我的游戏中的某些东西后面）？我认为在新的Unity 5.4中应用这个着色器不是强制性的。有人可以确认吗？你是否从硬纸板上观看应用程序硬纸板设计，有很多关于vr的提示或经验。