Delphi TChromium:GetSourceProc和不兼容类型：'；常规过程和方法指针'；

我需要从TChromium中加载的页面获取源HTML，但我需要将源代码存储在另一个类的变量中。换句话说，回调函数需要在另一个类中，我不能这样做，因为此异常：

E2009不兼容类型：“常规过程和方法指针”

这是我的密码。只有当“StringVisitor”函数在“Form1”类之外时，它才起作用

有什么想法吗

unit simple1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, cefvcl, ceflib;

type
  TForm1 = class(TForm)
    Chromium1: TChromium;
    procedure FormCreate(Sender: TObject);
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
      httpStatusCode: Integer);
  public
  mySource : string;
  procedure StringVisitor(const str: ustring);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
  httpStatusCode: Integer);
begin
  Chromium1.Browser.MainFrame.GetSourceProc(StringVisitor);  // error on this line
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
chromium1.load('http://www.google.com');
end;

procedure TForm1.StringVisitor(const str: ustring);
begin
mySource := str;
end;

end.

---

好的，使用Delphi7我可以重现这个问题

在深入研究这个问题之后，我发现有两种方法可以获取加载页面的源：

1） 过程GetSourceProc（const proc:TCefStringVisitorProc）当您使用时。该解决方案的问题是在Dlephi 2009之前，它只接受一个独立的过程，当您有多个要保存HTML的对象实例时，它会给您带来问题

2）

procedure-GetSource（const-visitor:ICefStringVisitor）

让我们先看看预期的接口

  ICefStringVisitor = interface(ICefBase)
    ['{63ED4D6C-2FC8-4537-964B-B84C008F6158}']
    procedure Visit(const str: ustring);
  end;

所以我开始调查这件事。挖掘后
单位ceflib
我找到了
TCefStringVisitorOwn
，这是解决方案的关键

TCefStringVisitorOwn
的界面非常简单：

  TCefStringVisitorOwn = class(TCefBaseOwn, ICefStringVisitor)
  protected
    procedure Visit(const str: ustring); virtual;
  public
    constructor Create; virtual;
  end;

因此，有了这个，我创建了
TCefStringVisitorOwn
的后代：

unit SourceContainerU;

interface

uses
  ceflib;

type
  ISourceContainer = interface(ICefStringVisitor)
    function Source: ustring;
  end;

  TSourceContainer = class(TCefStringVisitorOwn, ISourceContainer)
  private
    FSource: ustring;
  protected
    procedure Visit(const str: ustring); override;
  public
    function Source: ustring;
  end;

implementation

{ TSourceContainer }

function TSourceContainer.Source: ustring;
begin
  Result := FSource;
end;

procedure TSourceContainer.Visit(const str: ustring);
begin
  FSource := str;
end;

end.

这里没有什么神奇的

剩下的就是使用这个类创建一个演示项目。在我的示例中，我在运行时创建
tcromium
。表单包含一个按钮和一个备忘录，然后是以下代码：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls,
  cefvcl, ceflib, SourceContainerU;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    Chromium1: TChromium;
    SourceContainer : ISourceContainer;
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.Chromium1LoadEnd(Sender: TObject;  const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
begin
  if Frame = nil then
    exit;

  SourceContainer := TSourceContainer.Create;
  Frame.GetSource(SourceContainer);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Chromium1 := TChromium.Create(self);
  Chromium1.Parent := self;
  Chromium1.OnLoadEnd := Chromium1LoadEnd;
  Chromium1.load('http://www.google.com');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Assigned(SourceContainer) then
    Memo1.Lines.Text := SourceContainer.Source;
end;

end.

此解决方案已使用最新版本的铬进行了测试，我已在Delphi 7、Delphi XE和Delphi XE6中对其进行了测试。我没有任何Delphi2007安装，但我相信它也应该在wotk中工作
 我不确定传递给GetSourceProc的例程应该具有什么样的签名，但传统的方法（即在匿名方法和“引用过程”语法之前）是编写一个独立的过程MyProcedure传递给GetSourceProc，在MyProcedure内部只需调用Form1.StringVisitor。当然，Form1当时必须存在。错误很明显，stringvisitor必须是一个常规过程，而不是一个方法。您必须使用全局form1变量来访问表单对象……我刚刚下载了最新版本的Chromium（）并测试了您的示例。我在Delphi Xe6中编译得很好。@JensBorrisholt我在使用Delphi 2007，可能在Xe6中做了一些更改，允许我做我正在尝试的事情。@Whosrdad您能提供一些示例代码吗？如果我全局声明了StringVisitor，那么TForm1的所有实例都将共享同一个过程，并且我无法将结果存储在每个TForm1实例中……这种方法的问题是它将在TForm1的第一个实例“Form1”上工作。但是如果我创建更多的实例，比如Form2和Form3，我认为它不会工作，是吗？@delphirules我已经为您创建了一个新的解决方案。是否可以通过直接在表单中实现ICefStringVisitor来简化此过程？应该是可行的，问一个新问题，我将对此进行研究解决方案有效，非常感谢@JensBorrisholt:）