Xml XSLT：如果指定路径中存在子级，则返回true

如何检查指定路径中是否存在节点？ 例如，我有以下xml：

<?xml version="1.0" encoding="UTF-8"?>
<books>
  <bookgroup name="group1">
    <book name="BookName1"/>
    <book name="BookName2"/>
    <book name="BookName3"/>
    <book name="BookName4"/>
    <book name="BookName5"/>
  </bookgroup>
  <bookgroup name="group2">
    <book name="BookName6"/>
    <book name="BookName7"/>
  </bookgroup>
  <selected>
    <book name="BookName2"/>
    <book name="BookName3"/>
  </selected>
</books>

由于子节点BookName2和bookname3存在于所选标记中，因此Desired输出将为返回true；而由于其子节点均不在所选标记中，因此Desired输出为false

这就是我尝试过的：

    <xsl:template name="IsChildExist">
    <xsl:param name="bookGroupName"/>
    <xsl:variable name="isExist">
        <xsl:for-each select="//bookgoup[@NAME=$bookGroupName]/book">
            <xsl:variable name="childNode" select="./@name"/>
            <xsl:choose>
                <xsl:when test="count(//selected/book[@name=$childNode])>0">
                    <xsl:value-of select="true()"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="false()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>
    </xsl:variable>
    <xsl:value-of select="$isExist"/>
</xsl:template>

但仍在为每个循环的突破而战斗

---

提前感谢。

XSLT没有“打破”循环的概念。它是一种函数式语言，因此您需要改变您的思维方式，使之脱离命令式语言中的正常控制流

要解决您的特定问题，您可以使用一个键来查找选定的书籍

<xsl:key name="selected" match="selected/book" use="@name" />

实际上，您根本不需要为每个使用xsl:for。您可以查找以选择元素列表中是否有任何元素属于某个键，而不仅仅是某个特定元素

<xsl:template name="IsChildExist">
  <xsl:param name="bookGroupName" select="@name"/>
  <xsl:variable name="isExist">
     <xsl:choose>
        <xsl:when test="key('selected', //bookgroup[@name=$bookGroupName]/book/@name)">
           <xsl:value-of select="true()"/>
        </xsl:when>
        <xsl:otherwise>
           <xsl:value-of select="false()"/>
        </xsl:otherwise>
     </xsl:choose>
  </xsl:variable>
  <xsl:value-of select="$isExist"/>
</xsl:template>

但是，是否需要使用命名模板？根据您试图输出的内容，您可以使用XSLT中的正常tempate模式匹配来完成这项工作。试试这个XSL

<xsl:output method="xml" indent="yes"/>
   <xsl:key name="selected" match="selected/book" use="@name" />

   <xsl:template match="bookgroup[key('selected', book/@name)]">
      <bookgroup>
         <xsl:apply-templates select="@*"/>
         <xsl:text>TRUE</xsl:text>
      </bookgroup>
   </xsl:template>

   <xsl:template match="bookgroup">
      <bookgroup>
         <xsl:apply-templates select="@*"/>
         <xsl:text>FALSE</xsl:text>
      </bookgroup>
   </xsl:template>

   <xsl:template match="selected" />

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

真的
错误的

应用于示例XML时，将输出以下内容：

<books>
   <bookgroup name="group1">TRUE</bookgroup>
   <bookgroup name="group2">FALSE</bookgroup>
</books>

真的
错误的

@Anders Lindahl，我尝试创建一个模板，并在子节点之间循环，并对照所选节点进行检查，但在找出如何打破循环方面遇到了麻烦：（显示代码和期望的输出-不完全清楚你想要从转换中得到什么样的结果）@ Anders Lindahl，补充了我在这个问题中所尝试的，希望这帮助SpReNNA，考虑用XSLT把你想要创建的输出张贴到你已经发布的输入样本上，然后我们可以建议XSLT的方式来做这件事。调用模板时，ed输出对于bookgroup1为TRUE，对于bookgroup2为FALSE。