Encryption AES的输出块大小

我试着用一个16字节的键用拍子来处理16字节的块。我希望有一个16字节的输出块，但我得到了一个32字节的输出块。 15字节的输入块提供16位输出

#lang racket

(require (planet vyzo/crypto))

(bytes-length (encrypt cipher:aes-128-ecb
                       (string->bytes/latin-1 "0123456789ABCDEF") ; 16-byte key
                       (make-bytes 16) ; IV
                       (string->bytes/latin-1 "0123456789ABCDEF"))) ; 16-byte data
; -> 32

(bytes-length (encrypt cipher:aes-128-ecb
                       (string->bytes/latin-1 "0123456789ABCDEF") ; 16-byte key
                       (make-bytes 16)
                       (string->bytes/latin-1 "0123456789ABCDE"))) ; 15-byte data
; -> 16

我哪里错了？这是因为填充物吗

---

注意：我知道ECB模式的问题，我的目标是实现CBC模式。

看起来所有输入都被填充到下一个块边界。这意味着16字节的输入将以32字节填充到下一个边界。如果所有的输入都是精确的块大小，那么可以关闭填充。如果输入可以在块的中间结束，那么您将不得不离开填充开关。

---

如果要使用CBC模式，那么可能还需要考虑身份验证。如果您确实需要它，那么HMAC可能是最容易开始使用的。

您是对的，这是因为填充。不幸的是，的API不允许您轻松禁用填充（正确地说，请参见下面的警告）

如何禁用填充

但是，基于此，您可以如下方式禁用填充：

#lang racket

(require (planet vyzo/crypto) (planet vyzo/crypto/util))

(define (cipher-encrypt-unpadded type key iv)
  (lambda (ptext)
    (let ((octx (cipher-encrypt type key iv #:padding #f)))
      (bytes-append (cipher-update! octx ptext)
                    (cipher-final! octx)))))

(define (cipher-decrypt-unpadded type key iv)
  (lambda (ctext)
    (let ((ictx (cipher-decrypt type key iv #:padding #f)))
      (bytes-append (cipher-update! ictx ctext)
                    (cipher-final! ictx)))))

; bytes-> bytes
; convenience function for encryption
(define enc-aes-128-ecb-unpadded 
   (cipher-encrypt-unpadded cipher:aes-128-ecb 
                            (string->bytes/latin-1 "0123456789ABCDEF"); 16-byte key
                            (make-bytes 16)))

; bytes -> bytes
; convenience function for decryption       
(define dec-aes-128-ecb-unpadded 
   (cipher-decrypt-unpadded cipher:aes-128-ecb 
                            (string->bytes/latin-1 "0123456789ABCDEF"); 16-byte key
                            (make-bytes 16)))

(define message (string->bytes/latin-1 "0123456789ABCDEF")) ; 16-byte data

(bytes-length (enc-aes-128-ecb-unpadded message))
; -> 16


(dec-aes-128-ecb-unpadded (enc-aes-128-ecb-unpadded message))
; -> #"0123456789ABCDEF"

这在我的机器上运行得很好。此外，切换到CBC模式也很简单

警告

禁用填充时，消息的长度必须是块大小的倍数。对于AES128，这是16字节的精确倍数。否则，该功能将在您的脸上爆炸：

(enc-aes-128-ecb-unpadded (string->bytes/latin-1 "too short!"))
EVP_CipherFinal_ex: libcrypto error: data not multiple of block length [digital envelope routines:EVP_EncryptFinal_ex:101183626] 

---

谢谢。正是我需要的。