Process 监视来自AHK的衍生进程（进程树）

我一直在搜索引擎上搜索，所以，AHK论坛没有成功，如何获得通过Run[Wait]命令运行的任何内容的层次结构树的PID

---

任何帮助/指导都将不胜感激。

通过20次迭代寻找30个子流程树，我的平均时间为：

动态链接库：0.2587435 WMI:0.1113015 这是长凳：

pid := 7880
loops := 20

time_dll := 0
Loop, % loops
{
    QPC(1)
    tree_dll := processTree(pid)
    time_dll += QPC()
}
time_dll /= loops

time_wmi := 0
Loop, % loops
{
    QPC(1)
    tree_wmi := processTree(pid, True)
    time_wmi += QPC()
}
time_wmi /= loops

MsgBox,,>, % "DLL: " time_dll "`nWMI: " time_wmi

;-------------------------------------------------------------------------------

processTree(pid, wmi := False, obj := False)
{
    Local
    tree := []
    If wmi
    {
        If !obj
            obj := ComObjGet("winmgmts:").ExecQuery("SELECT ProcessId,ParentProcessId FROM Win32_Process")
        tree := []
        For result in obj
            If pid = result.ParentProcessId
            {
                tree.Push(result.ProcessId)
                subs := %A_ThisFunc%(result.ProcessId, True, obj)
                For idx,val in subs
                    tree.Push(val)
            }
    }
    Else
    {
        Static MAX_PATH := 260 << !!A_IsUnicode
        Static varCapacity := MAX_PATH
        VarSetCapacity(lppe, varCapacity)
        NumPut(varCapacity, lppe, "UInt")
        hSnapshot := DllCall("CreateToolhelp32Snapshot", "UInt",0x2, "UInt",pid, "Ptr")
        DllCall("Process32First", "Ptr",hSnapshot, "Ptr",&lppe)
        Loop
        {
            parent := NumGet(lppe, 16 + A_PtrSize * 2, "UInt")
            If (parent = pid)
            {
                child := NumGet(lppe, 8, "UInt")
                tree.Push(child)
                gchilds := %A_ThisFunc%(child)
                For idx,val in gchilds
                    tree.Push(val)
            }
        } Until !DllCall("Process32Next", "Ptr",hSnapshot, "Ptr",&lppe)
        DllCall("CloseHandle", "Ptr",hSnapshot)
    }
    Return, tree
}

QPC(start := 0)
{
    Static P := 0, F := 0, Q := DllCall("QueryPerformanceFrequency", "Int64P",F)
    Return !DllCall("QueryPerformanceCounter", "Int64P",Q) + (start ? (P:=Q)/F : (Q-P)/F)
}

---

您可以通过WinAPI查询流程详细信息，AHK示例。通过递归读取ParentProcessId，您可以构建任何根进程的进程树。谢谢，我这么做了，它太慢了，我简直不敢相信。我将等待另一个答案，同时我有一个工作DLL调用，它做得更好。如果没有消息，将作为答案发布。立即：您可能正在调用Select*。。。多次，这可能是性能不佳的原因。尝试一次选择所有进程并处理内存中的数据。再说一次，为什么不在这里发布代码以便我们一起改进呢？不，我只是选择了ProcessId，ParentProcessId，其中ParentProcessId=pid。OTOH，选择所有PID并为earch child迭代更好。我真傻，这样的疏忽。非常感谢，先生，很好。通过父PID排序和进行二进制搜索，您可能会得到提升。这将大大减少查找的数量。或者同样有希望且更容易实现：构建您自己的对象/字典，并按父PID对所有进程进行分组。我喜欢这个想法，但那只是过火了。。。这将是用户交互的一部分，因此十分之一秒似乎是公平的交易。非常感谢您的帮助和见解。