Export 有没有办法将整个笔记本电脑的不同部分导出

我正在寻找将evernote笔记本导出到不同部件的可能性，如：

笔记本=Eingang 2000Notes

出口到也许

Eingang1.enex 500注释 Eingang2.enex 500注释 Eingang3.enex 500注释 Eingang3.enex 500注释 因为处理（即导入Onenote）经常失败，原因是ENEX文件中的笔记太多或太大。 也许有一些脚本或其他任何东西可以工作。仅通过手工导出不是一种正确的方式，因为我有14k+笔记的笔记本。 我希望我的意图越来越清楚。

---

提前感谢您的帮助

如果您在Mac电脑上，Evernote的AppleScript字典会公开一个导出谓词，您可以根据它构建工具。下面是一个有点不雅观但功能强大的AppleScript，用于完成您想要的任务，只需编辑批量大小、笔记本名称以及希望ENEX文件进入的路径即可：

tell application "Evernote"
    # Set batch size, notebook to export, and destination path
    set batchSize to 500
    set theNotebookName to "MyNotebook"
    set theExportFolder to "/tmp"

    # Enumerate the notes into batches and export them
    set theNotebook to the first notebook whose name is theNotebookName
    set theNotes to the notes in theNotebook
    set currentBatchIndex to 0
    set currentNoteIndex to 1
    repeat until currentNoteIndex = (count of theNotes)
        # Collect up to batchSize notes
        set thisExportBatch to {}
        repeat until ((count of thisExportBatch) = batchSize or (currentNoteIndex = (count of theNotes)))
            set currentItem to theNotes's item currentNoteIndex
            set thisExportBatch to thisExportBatch & {currentItem}
            set currentNoteIndex to currentNoteIndex + 1
        end repeat
        # Export this batch. Set the destination path to where you want them.
        set exportPath to (theExportFolder & "/" & theNotebookName & currentBatchIndex & ".enex")
        export thisExportBatch to exportPath
        set currentBatchIndex to (currentBatchIndex + 1)
    end repeat
end tell

我不确定Windows上的等价物是什么，但我希望有一些等价的方法来自动化它